gnome-disk-utility/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Silvio Knizek (killermoehre)
   4
   5 pkgname=gnome-disk-utility
   6 pkgver=42.0
   7 pkgrel=1
   8 pkgdesc="Disk Management Utility for GNOME"
   9 url="https://gitlab.gnome.org/GNOME/gnome-disk-utility"
  10 arch=(x86_64)
  11 license=(GPL)
  12 groups=(gnome)
  13 depends=(udisks2 gtk3 libsecret libpwquality libcanberra libdvdread libnotify
  14          parted systemd libhandy)
  15 makedepends=(git meson docbook-xsl)
  16 options=(debug)
  17 _commit=5f6488fc9660de73048d247da4fd0eecdd0a21a6  # tags/42.0^0
  18 source=("git+https://gitlab.gnome.org/GNOME/gnome-disk-utility.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 build() {
  27   arch-meson $pkgname build
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   meson install -C build --destdir "$pkgdir"
  37 }