at-spi2-atk/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=at-spi2-atk
   5 pkgver=2.38.0
   6 pkgrel=1
   7 pkgdesc="A GTK+ module that bridges ATK to D-Bus at-spi"
   8 url="https://wiki.gnome.org/Accessibility"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(at-spi2-core libx11 libxml2 atk)
  12 makedepends=(git meson)
  13 _commit=b91a111f040a09e804428a81e6de214e4962247b  # tags/AT_SPI2_ATK_2_38_0^0
  14 source=("git+https://gitlab.gnome.org/GNOME/at-spi2-atk.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/^AT_SPI2_ATK_//;s/_/./g;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24 }
  25
  26 build() {
  27   arch-meson $pkgname build
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   dbus-run-session meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   DESTDIR="$pkgdir" meson install -C build
  37 }
  38
  39 # vim:set ts=2 sw=2 et: