mono-tools/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Daniel Isenmann <daniel@archlinux.org>
   2 # Contributor: Brice Carpentier <brice@dlfp.org>
   3
   4 # The mono-tool package now calls make-search-index by post_install().
   5 # Whenever a package is installed which places doc-sources into:
   6 # /usr/lib/monodoc/sources it should call --make-search-index with
   7 # post_install() and with post remove. mond-tools itself deletes the index
   8 # file pre_remove(), so pacman finds the directory empty an removes it
   9 # properly.
  10
  11 pkgname=mono-tools
  12 pkgver=4.2
  13 pkgrel=2
  14 pkgdesc="collection of testing and development tools for use with mono (including monodoc browser)"
  15 arch=(x86_64)
  16 license=('GPL')
  17 url="http://www.mono-project.com/"
  18 depends=('gtk-sharp-2')
  19 makedepends=('git' 'zip')
  20 install=$pkgname.install
  21 options=('!makeflags')
  22 source=($pkgname-$pkgver.tar.gz::https://github.com/mono/mono-tools/archive/$pkgver.tar.gz
  23         monodoc.xml)
  24 sha256sums=('104f7a7e98202c44cd4f025ab8a922bd193e83ce874a48e50ffb401128ca73a8'
  25             '80de1af405556addbb481d9ac123e5f94b08ad7869c90fb469d71eb08c941480')
  26
  27 prepare() {
  28   cd $pkgname-$pkgver
  29   mv configure.in configure.ac
  30
  31   sed -e 's/-warnaserror+//' -i gendarme/options.make # Fix build with newer mono
  32 }
  33
  34 build() {
  35   cd $pkgname-$pkgver
  36   glib-gettextize --force
  37   autoreconf -fi
  38   GMCS=/usr/bin/dmcs ./configure --prefix=/usr
  39   make
  40 }
  41
  42 package() {
  43   cd $pkgname-$pkgver
  44   make DESTDIR="$pkgdir" install
  45   install -D -m644 "${srcdir}"/monodoc.xml "${pkgdir}"/usr/lib/monodoc/monodoc.xml
  46 }