totem/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=totem
   5 pkgver=42.0
   6 pkgrel=1
   7 pkgdesc="Movie player for the GNOME desktop based on GStreamer"
   8 url="https://wiki.gnome.org/Apps/Videos"
   9 arch=(x86_64)
  10 license=(GPL2 custom)
  11 depends=(totem-plparser iso-codes libpeas grilo gsettings-desktop-schemas
  12          python-gobject gnome-desktop gst-plugins-base gst-plugins-good
  13          gst-plugins-bad gst-plugin-gtk libhandy)
  14 makedepends=(libnautilus-extension itstool docbook-xsl python-pylint
  15              gobject-introspection git appstream-glib gtk-doc meson intltool)
  16 optdepends=('gst-plugins-ugly: Extra media codecs'
  17             'gst-libav: Extra media codecs'
  18             'grilo-plugins: Media discovery')
  19 conflicts=(totem-plugin)
  20 replaces=(totem-plugin)
  21 groups=(gnome)
  22 options=(debug)
  23 _commit=d578333de76dc51f7a58bd84edee8ee93f5050e3  # tags/42.0^0
  24 source=("git+https://gitlab.gnome.org/GNOME/totem.git#commit=$_commit"
  25         "git+https://gitlab.gnome.org/GNOME/libgd.git")
  26 sha256sums=('SKIP'
  27             'SKIP')
  28
  29 pkgver() {
  30   cd totem
  31   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  32 }
  33
  34 prepare() {
  35   cd totem
  36
  37   git submodule init
  38   git submodule set-url subprojects/libgd "$srcdir/libgd"
  39   git submodule update
  40 }
  41
  42 build() {
  43   arch-meson totem build -D enable-gtk-doc=true
  44   meson compile -C build
  45 }
  46
  47 package() {
  48   meson install -C build --destdir "$pkgdir"
  49   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 totem/COPYING
  50 }