xdg-user-dirs-gtk/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=xdg-user-dirs-gtk
   4 pkgver=0.11
   5 pkgrel=1
   6 pkgdesc="Creates user dirs and asks to relocalize them"
   7 url="https://gitlab.gnome.org/GNOME/xdg-user-dirs-gtk"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(gtk3 xdg-user-dirs)
  11 makedepends=(intltool git)
  12 groups=(gnome)
  13 _commit=cf2a85fa5370aa7cdf36d1c8259ca89d3d737ef9  # tags/0.11^0
  14 source=("git+https://gitlab.gnome.org/GNOME/xdg-user-dirs-gtk.git#commit=$_commit"
  15         show-in-mate.diff)
  16 sha256sums=('SKIP'
  17             '80bd751b9bfc95e06775da31ff1ae32417bfca2df3b9e063d478b056834224f3')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26   git apply -3 ../show-in-mate.diff
  27   autoreconf -fvi
  28 }
  29
  30 build() {
  31   cd $pkgname
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  33     --disable-more-warnings
  34   make
  35 }
  36
  37 package() {
  38   cd $pkgname
  39   make DESTDIR="$pkgdir" install
  40 }
  41
  42 # vim:set sw=2 sts=-1 et: