bison/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: Allan McRae <allan@archlinux.org>
   3 # Contributor: Eric Belanger <eric@archlinux.org>
   4
   5 pkgname=bison
   6 pkgver=3.8.2
   7 pkgrel=4
   8 pkgdesc="The GNU general-purpose parser generator"
   9 arch=('x86_64')
  10 license=('GPL3')
  11 url="https://www.gnu.org/software/bison/bison.html"
  12 depends=('glibc' 'm4' 'sh' 'gettext')
  13 groups=('base-devel')
  14 source=("https://ftp.gnu.org/gnu/bison/${pkgname}-${pkgver}.tar.xz"{,.sig})
  15 sha512sums=('d4d23af6671406e97257892f90651b67f2ab95219831372be032190b7156c10a3435d457857e677445df8b2327aacccc15344acbbc3808a6f332a93cce23b444'
  16             'SKIP')
  17 validpgpkeys=('7DF84374B1EE1F9764BBE25D0DDCAA3278D5264E')  # Akim Demaille
  18
  19 build() {
  20   cd "${srcdir}/${pkgname}-${pkgver}"
  21
  22   CFLAGS+=' -ffat-lto-objects' \
  23   ./configure --prefix=/usr --datadir=/usr/share
  24   make
  25 }
  26
  27 check() {
  28   cd "${srcdir}/${pkgname}-${pkgver}"
  29   make check
  30 }
  31
  32 package() {
  33   cd "${srcdir}/${pkgname}-${pkgver}"
  34   make DESTDIR="${pkgdir}" install
  35 }