conky/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4 # Contributor: James Rayner <james@archlinux.org>
   5 # Contributor: Partha Chowdhury <kira.laucas@gmail.com>
   6
   7 pkgname=conky
   8 pkgver=1.15.0
   9 _gitcommit=70d7d5c796e3e84e674705ffc6aaf7a0d6c5b109
  10 pkgrel=1
  11 pkgdesc='Lightweight system monitor for X'
  12 url='https://github.com/brndnmtthws/conky'
  13 license=('BSD' 'GPL')
  14 arch=('x86_64')
  15 makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git' 'catch2' 'pandoc' 'python-yaml' 'python-jinja')
  16 depends=(
  17   'glibc' 'glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft' 'imlib2'
  18   'libxml2' 'libpulse' 'libxnvctrl' 'systemd-libs' 'ncurses' 'curl'
  19   libncursesw.so libXNVCtrl.so libsystemd.so libpulse.so libcurl.so)
  20 source=("git+https://github.com/brndnmtthws/conky.git#commit=${_gitcommit}?signed")
  21 sha512sums=('SKIP')
  22 b2sums=('SKIP')
  23 validpgpkeys=(
  24   'EB2E847572A71BE20F59AFBEB49ABB7270D9D4FD' # Brenden Matthews
  25 )
  26
  27 pkgver() {
  28   cd ${pkgname}
  29   git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  30 }
  31
  32 prepare() {
  33   cd $pkgname
  34 # Unbundle catch2 to fix build with glibc 2.35
  35   rm -r tests/catch2
  36   ln -s /usr/include/catch2 tests
  37 }
  38
  39 build() {
  40   cd ${pkgname}
  41   cmake \
  42     -B build \
  43     -D CMAKE_BUILD_TYPE=Release \
  44     -D CMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects" \
  45     -D MAINTAINER_MODE=ON \
  46     -D BUILD_DOCS=ON \
  47     -D BUILD_EXTRAS=ON \
  48     -D BUILD_WLAN=ON \
  49     -D BUILD_XDBE=ON \
  50     -D BUILD_XSHAPE=ON \
  51     -D BUILD_IMLIB2=ON \
  52     -D BUILD_CURL=ON \
  53     -D BUILD_RSS=ON \
  54     -D BUILD_NVIDIA=ON \
  55     -D BUILD_WEATHER_METAR=ON \
  56     -D BUILD_PULSEAUDIO=ON \
  57     -D BUILD_JOURNAL=ON \
  58     -D CMAKE_INSTALL_PREFIX=/usr \
  59     -Wno-dev \
  60     -S .
  61
  62   make -C build
  63 }
  64
  65 package() {
  66   cd ${pkgname}
  67   make -C build DESTDIR="${pkgdir}" install
  68   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  69   install -Dm 644 build/extras/vim/syntax/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/syntax
  70   install -Dm 644 extras/vim/ftdetect/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/ftdetect
  71 }
  72
  73 # vim: ts=2 sw=2 et: