libssh2/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Dave Reisner <dreisner@archlinux.org>
   2 # Contributor: Angel Velasquez <angvp@archlinux.org>
   3 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   4 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   5 # Contributor: ice-man <icemanf@gmail.com>
   6
   7 pkgname=libssh2
   8 pkgver=1.10.0
   9 pkgrel=3
  10 pkgdesc="A library implementing the SSH2 protocol as defined by Internet Drafts"
  11 url="https://www.libssh2.org/"
  12 arch=('x86_64')
  13 license=('BSD')
  14 depends=('openssl' 'zlib')
  15 provides=('libssh2.so')
  16 validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2'   # Daniel Stenberg
  17               '914C533DF9B2ADA2204F586D78E11C6B279D5C91')  # Daniel Stenberg (old key)
  18 source=("https://www.libssh2.org/download/$pkgname-$pkgver.tar.gz"{,.asc})
  19 sha256sums=('2d64e90f3ded394b91d3a2e774ca203a4179f69aebee03003e5a6fa621e41d51'
  20             'SKIP')
  21
  22 build() {
  23   cd "$pkgname-$pkgver"
  24
  25   ./configure --prefix=/usr
  26   make
  27 }
  28
  29 check() {
  30   make -C "$pkgname-$pkgver" check
  31 }
  32
  33 package() {
  34   cd "$pkgname-$pkgver"
  35
  36   make DESTDIR="$pkgdir" install
  37   install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  38 }