lm_sensors/trunk/PKGBUILD

   1 # Maintainer: Laurent Carlier <lordheavym@gmail.com>
   2 # Contributor: Eric Bélanger
   3
   4 pkgname=lm_sensors
   5 pkgver=3.6.0.r41.g31d1f125
   6 _commit=31d1f125d8076f1c8c8f3224b31d240e6e6a1763
   7 #_pkgver=${pkgver//./-}
   8 pkgrel=2
   9 epoch=1
  10 pkgdesc="Collection of user space tools for general SMBus access and hardware monitoring"
  11 arch=('x86_64')
  12 url="https://hwmon.wiki.kernel.org/lm_sensors"
  13 license=('GPL' 'LGPL')
  14 optdepends=('rrdtool: for logging with sensord'
  15             'perl: for sensor detection and configuration convert')
  16 makedepends=('rrdtool' 'perl' 'git')
  17 provides=('libsensors.so')
  18 backup=('etc/sensors3.conf' 'etc/healthd.conf' 'etc/conf.d/sensord')
  19 options=('debug')
  20 #source=(lm_sensors-${pkgver}.tar.gz::https://github.com/lm-sensors/lm-sensors/archive/V${_pkgver}.tar.gz
  21 source=("git+https://github.com/groeck/lm-sensors.git#commit=${_commit}"
  22         healthd healthd.conf healthd.service sensord.conf)
  23 sha256sums=('SKIP'
  24             '0ac9afb2a9155dd74ab393756ed552cd542dde1081149beb2ab4ec7ff55b8f4a'
  25             '5d17a366b175cf9cb4bb0115c030d4b8d91231546f713784a74935b6e533da9f'
  26             '2638cd363e60f8d36bcac468f414a6ba29a1b5599f40fc651ca953858c8429d7'
  27             '23bebef4c250f8c0aaba2c75fd3d2c8ee9473cc91a342161a9f5b3a34ddfa9e5')
  28 validpgpkeys=('7CA69F4460F1BDC41FD2C858A5526B9BB3CD4E6A')
  29
  30 pkgver() {
  31   cd "${srcdir}"/lm-sensors*
  32
  33   git describe --long --tags | sed 's/V//;s/\([^-]*-g\)/r\1/;s/-/./g'
  34 }
  35
  36 prepare() {
  37   cd "${srcdir}"/lm-sensors*
  38   sed -i 's|/etc/sysconfig|/etc/conf.d|' prog/{detect/sensors-detect,init/{sensord,lm_sensors}.service}
  39   sed -i 's/EnvironmentFile=/EnvironmentFile=-/' prog/init/lm_sensors.service
  40 }
  41
  42 build() {
  43   cd "${srcdir}"/lm-sensors*
  44   make PREFIX=/usr
  45 }
  46
  47 package() {
  48   cd "${srcdir}"/lm-sensors*
  49   make PROG_EXTRA=sensord BUILD_STATIC_LIB=0 \
  50     PREFIX=/usr SBINDIR=/usr/bin MANDIR=/usr/share/man DESTDIR="${pkgdir}" install
  51
  52   install -D -m755 "${srcdir}/healthd" "${pkgdir}/usr/bin/healthd"
  53
  54   install -D -m644 "${srcdir}/healthd.conf" "${pkgdir}/etc/healthd.conf"
  55   install -D -m644 "${srcdir}/sensord.conf" "${pkgdir}/etc/conf.d/sensord"
  56
  57   install -D -m644 "${srcdir}/healthd.service" "${pkgdir}/usr/lib/systemd/system/healthd.service"
  58   install -D -m644 prog/init/*.service "${pkgdir}/usr/lib/systemd/system/"
  59 }