gegl/trunk/PKGBUILD

   1 # Maintainer: Daniel Isenmann <daniel@archlinux.org>
   2
   3 pkgname=gegl
   4 _tag='1d26feb07a7221b9d386b54bcdad963c8421e594'
   5 pkgver=0.4.40
   6 pkgrel=4
   7 pkgdesc='Graph based image processing framework'
   8 arch=('x86_64')
   9 url='https://www.gegl.org/'
  10 license=('GPL3' 'LGPL3')
  11 depends=('babl' 'jasper' 'json-glib' 'lensfun' 'libgexiv2' 'libraw' 'librsvg' 'libspiro'
  12          'libtiff' 'luajit' 'openexr' 'poppler-glib' 'suitesparse')
  13 makedepends=('exiv2' 'ffmpeg' 'git' 'glu' 'gobject-introspection' 'intltool' 'mesa'
  14              'meson' 'python-gobject' 'ruby' 'vala')
  15 optdepends=('ffmpeg: ffmpeg plugin'
  16             'graphviz: for gegl-introspect')
  17 source=("git+https://gitlab.gnome.org/GNOME/gegl.git#tag=$_tag"
  18          gegl-libraw-0.21.patch)
  19 sha256sums=('SKIP'
  20             '16bfd56e3139dba47f4839e46d27df339a1ed9f57c63b58cb071713c5741c8c7')
  21
  22 pkgver() {
  23   cd "${pkgname}"
  24   git describe --tags | sed 's/^GEGL_//;s/_$//;s/_/./g;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   patch -d $pkgname -p1 < gegl-libraw-0.21.patch # Fix build with libraw 0.21
  29 }
  30
  31 build() {
  32   mkdir -p build
  33   cd build
  34   arch-meson ../"${pkgname}" \
  35     -Dworkshop=true \
  36     -Dmrg=disabled \
  37     -Dmaxflow=disabled
  38   ninja
  39 }
  40
  41 check() {
  42   cd build
  43   ninja test || :
  44 }
  45
  46 package() {
  47   cd build
  48   DESTDIR="${pkgdir}" ninja install
  49 }