dep/ACE_wrappers/m4/ace_headers.m4

   1 # ACE_CHECK_HAS_HEADERS(HEADER-FILE...,
   2 #                       [ACTION-IF-FOUND],
   3 #                       [ACTION-IF-NOT-FOUND],
   4 #                       [INCLUDES = 'default-includes'])
   5 #-----------------------------------------------------------------------------
   6 AC_DEFUN([ACE_CHECK_HAS_HEADERS],
   7 [AC_FOREACH([ACE_Header], [$1],
   8   [AH_TEMPLATE(AS_TR_CPP([ACE_HAS_]ACE_Header),
   9                [Define to 1 if platform has the <]ACE_Header[> header file.])])dnl
  10 for ace_header in $1
  11 do
  12 AC_CHECK_HEADER($ace_header,
  13                 [AC_DEFINE_UNQUOTED(AS_TR_CPP([ACE_HAS_$ace_header])) $2],
  14                 [$3],
  15                 [$4])dnl
  16 done
  17 ])
  18
  19 # ACE_CHECK_LACKS_HEADERS(HEADER-FILE...,
  20 #                         [ACTION-IF-FOUND],
  21 #                         [ACTION-IF-NOT-FOUND],
  22 #                         [INCLUDES = 'default-includes'])
  23 #-----------------------------------------------------------------------------
  24 AC_DEFUN([ACE_CHECK_LACKS_HEADERS],
  25 [AC_FOREACH([ACE_Header], [$1],
  26   [AH_TEMPLATE(AS_TR_CPP([ACE_LACKS_]ACE_Header),
  27                [Define to 1 if platform lacks the <]ACE_Header[> header file.])])dnl
  28 for ace_header in $1
  29 do
  30 AC_CHECK_HEADER($ace_header,
  31                 [$2],
  32                 [AC_DEFINE_UNQUOTED(AS_TR_CPP([ACE_LACKS_$ace_header])) $3],
  33                 [$4])dnl
  34 done
  35 ])