clementine-git-no-sort-hack/PKGBUILD

   1 # Original-Maintainer: Adria Arrufat <swiftscythe@gmail.com>
   2 # Contributor: Ike Devolder <ike.devolder@gmail.com>
   3 # Contributor: Daniel Hill <daniel.hill@orcon.net.nz>
   4 # Contributor: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
   5 # Maintainer: Andreas Eisele <a.e@lupuz.de>
   6
   7 pkgname=clementine-git-no-sort-hack
   8 _realname=clementine-player
   9 pkgver=20111219
  10 pkgrel=1
  11 pkgdesc="A modern music player and library organiser and a port of Amarok 1.4, with some features rewritten to take advantage of Qt4. - Track Sorting disabled"
  12 arch=('i686' 'x86_64')
  13 url="http://code.google.com/p/clementine-player/"
  14 license=('GPL')
  15 depends=('gstreamer0.10-base' 'taglib' 'glew' 'liblastfm' 'libgpod' 'libmtp' 'libplist' 'hicolor-icon-theme' 'qt' 'libimobiledevice' 'libspotify' 'python2-pyqt' 'qjson' 'protobuf' 'libcdio')
  16 optdepends=('gstreamer0.10-base-plugins: for more open formats'
  17             'gstreamer0.10-good-plugins: for use with "Good" plugin libraries'
  18             'gstreamer0.10-bad-plugins: for use with "Bad" plugin libraries'
  19             'gstreamer0.10-ugly-plugins: for use with "Ugly" plugin libraries')
  20 makedepends=('git' 'boost' 'cmake' 'mesa')
  21 provides=('clementine')
  22 conflicts=('clementine' 'clementine-svn' 'clementine-git')
  23 replaces=('clementine' 'clementine-svn')
  24 source=(no-sort.patch)
  25 md5sums=('aa758764aa76c769fa9c9a5d95651352')
  26
  27 _gitroot="https://code.google.com/p/${_realname}"
  28 _gitname=${_realname}
  29
  30 build() {
  31   cd "${srcdir}"
  32   msg "Connecting to GIT server...."
  33
  34   if [[ -d "${_gitname}" ]]; then
  35     cd "${_gitname}" && git pull origin
  36     msg "The local files are updated."
  37   else
  38     git clone "${_gitroot}" "${_gitname}"
  39   fi
  40
  41   msg "GIT checkout done or server timeout"
  42   msg "Starting build..."
  43
  44   rm -rf "${srcdir}/${_gitname}-build"
  45   git clone "${srcdir}/${_gitname}" "${srcdir}/${_gitname}-build"
  46   cd "${srcdir}/${_gitname}-build"
  47
  48   patch -p1 < ${srcdir}/no-sort.patch
  49
  50   cmake . -DCMAKE_INSTALL_PREFIX=/usr -DBUILDBOT_REVISION=${pkgver}
  51   make
  52 }
  53
  54 package() {
  55   cd "${srcdir}/${_gitname}-build"
  56
  57   #OMG gigantic sed line that fixes the "blob" install error
  58   sed -i -e '/"\/.*version[[:digit:]]*[-]*[[:digit:]]*bit/ s//"${CMAKE_INSTALL_PREFIX}\/bin/' -e '/clementine-spotifyblob/ s/$ENV{DESTDIR}//g' spotifyblob/blob/cmake_install.cmake
  59
  60   make DESTDIR="${pkgdir}" install
  61 }
  62
  63 # vim:set ts=2 sw=2 et: