log4net/PKGBUILD

   1 # Maintainer: György Balló <ballogy@freestart.hu>
   2 # Contributor: Frane Bandov <frane@offbyte.com>
   3 # Contributor: Thijs Vermeir <thijsvermeir@gmail.com>
   4
   5 pkgname=log4net
   6 pkgver=1.2.11
   7 pkgrel=1
   8 pkgdesc="A tool to help the programmer output log statements to a variety of output targets"
   9 arch=('any')
  10 url="http://logging.apache.org/log4net/"
  11 license=('APACHE')
  12 depends=('mono')
  13 source=(http://www.apache.org/dist/logging/$pkgname/source/$pkgname-$pkgver-src.zip
  14         $pkgname.pc)
  15 md5sums=('64f9ba6cfb76ee5c7fa5c9c247c30203'
  16          '4e8f14ac075fcaaf642df5d11fcf2193')
  17
  18 build() {
  19   cd "$srcdir/$pkgname-$pkgver"
  20   mkdir bin
  21
  22   gmcs -t:library -out:bin/$pkgname.dll -keyfile:$pkgname.snk \
  23        -r:System,System.Data,System.Xml,System.Web \
  24        $(find src -name "*.cs")
  25 }
  26
  27 package() {
  28   cd "$srcdir/$pkgname-$pkgver"
  29
  30   gacutil -i bin/$pkgname.dll -package $pkgname -root "$pkgdir/usr/lib/"
  31   install -Dm644 "$srcdir/$pkgname.pc" "$pkgdir/usr/lib/pkgconfig/$pkgname.pc"
  32 }