pulseaudio-null/PKGBUILD

   1 pkgbase=pulseaudio-null
   2 pkgname=(pulseaudio-null)
   3 realbase=pulseaudio
   4 realname=(pulseaudio)
   5 pkgdesc="A featureful, general-purpose sound server"
   6 pkgver=1.1
   7 pkgrel=1
   8 arch=(i686 x86_64)
   9 url="http://pulseaudio.org/"
  10 license=(GPL LGPL)
  11 makedepends=(libasyncns libcap attr libxtst libsm libsamplerate libtool rtkit
  12              speex tdb udev dbus-core xcb-util avahi bluez gconf intltool jack
  13              lirc-utils openssl fftw orc json-c)
  14 options=(!emptydirs !libtool !buildflags)
  15 source=(http://freedesktop.org/software/$realbase/releases/$realbase-$pkgver.tar.xz
  16         $pkgbase.xinit)
  17
  18 build() {
  19   cd "$srcdir/$realbase-$pkgver"
  20
  21   ./configure --prefix=/usr \
  22     --sysconfdir=/etc \
  23     --libexecdir=/usr/lib \
  24     --localstatedir=/var \
  25     --with-database=tdb \
  26     --disable-hal \
  27     --disable-tcpwrap \
  28     --disable-rpath \
  29     --disable-default-build-tests
  30
  31   make
  32 }
  33
  34 package_pulseaudio-null() {
  35   depends=("libpulse=$pkgver-$pkgrel" rtkit libtool speex tdb udev fftw orc
  36            libsamplerate)
  37   optdepends=('avahi: zeroconf support'
  38               'bluez: bluetooth support'
  39               'gconf: configuration through gconf (paprefs)'
  40               'jack: jack support'
  41               'lirc-utils: infra-red support'
  42               'openssl: RAOP support'
  43               'python2-pyqt: Equalizer GUI (qpaeq)')
  44   conflicts=('pulseaudio')
  45   provides=("pulseaudio=${pkgver}")
  46   backup=(etc/pulse/{daemon.conf,default.pa,system.pa})
  47   install=pulseaudio.install
  48   cd "$srcdir/$realbase-$pkgver"
  49   make DESTDIR="$pkgdir" install
  50
  51   # Lower resample quality, saves CPU
  52   sed -e '/resample-method/iresample-method=speex-float-0' \
  53       -i "$pkgdir/etc/pulse/daemon.conf"
  54
  55   # Disable cork-request module, can result in e.g. media players unpausing
  56   # when there's a Skype call incoming
  57   sed -e 's|/usr/bin/pactl load-module module-x11-cork-request|#&|' \
  58       -i "$pkgdir/usr/bin/start-$realbase-x11"
  59
  60   # Make some modules optional
  61   sed -e $'/load-module module-console-kit/{i.nofail\n;a.fail\n;}' \
  62       -e '/load-module module-jackdbus-detect/s/^/#/' \
  63       -i "$pkgdir/etc/pulse/default.pa"
  64
  65   # Python fix
  66   sed -i '1s:python$:&2:' "$pkgdir/usr/bin/qpaeq"
  67
  68   install -Dm755 "$srcdir/$pkgbase.xinit" "$pkgdir/etc/X11/xinit/xinitrc.d/$pkgbase"
  69
  70   rm "$pkgdir/etc/dbus-1/system.d/$realbase-system.conf"
  71
  72 ### Split libpulse
  73
  74   mkdir -p "$srcdir"/libpulse/{etc/pulse,usr/{lib,share/man/man5}}
  75
  76   mv {"$pkgdir","$srcdir/libpulse"}/etc/pulse/client.conf
  77
  78   mv "$pkgdir"/usr/lib/libpulse{,dsp,-simple,-mainloop-glib}.so* \
  79      "$pkgdir"/usr/lib/libpulsecommon-*.so \
  80      "$srcdir/libpulse/usr/lib"
  81
  82   mv {"$pkgdir","$srcdir/libpulse"}/usr/lib/pkgconfig
  83   mv {"$pkgdir","$srcdir/libpulse"}/usr/include
  84
  85   mv {"$pkgdir","$srcdir/libpulse"}/usr/share/man/man5/pulse-client.conf.5
  86   mv {"$pkgdir","$srcdir/libpulse"}/usr/share/vala
  87 }
  88
  89 sha256sums=('6fe531136f6ebce2d35872a2d2c914278cdc5dcdd5eea516dc52c81f9001f5ee'
  90             'da58c590dacf0fdd4b9076eb71f4de5db2cfb98fe81a44ed652a6478611a1ce5')