gnomebaker/PKGBUILD

   1 # Maintainer: Phillip Smith <fukawi2@NO-SPAM.gmail.com>
   2 # http://github.com/fukawi2/aur-packages
   3 # Contributor: Gary Wright <wriggary@gmail.com>
   4 # Contributor: Allan McRae <allan@archlinux.org>
   5 # Contributor: Christopher Cox <nuopus@gmail.com>
   6
   7 pkgname=gnomebaker
   8 pkgver=0.6.4
   9 pkgrel=2
  10 pkgdesc="GnomeBaker is a full featured CD/DVD burning application for Gnome"
  11 license=('GPL')
  12 arch=('i686' 'x86_64')
  13 url="http://gnomebaker.sourceforge.net"
  14 install=gnomebaker.install
  15 depends=('libgnomeui' 'dvd+rw-tools' 'cdrkit' 'cdrdao' 'gstreamer0.10-base-plugins' 'libnotify')
  16 makedepends=('perlxml' 'rarian' 'patch')
  17 source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz"
  18         'gnomebaker-0.6.4-libnotify-0.7.patch')
  19 md5sums=('db43492684e0ba349be85e81ce0a9e56'
  20          '137f6b576d0d49990ac5b9c34bc2fbc9')
  21
  22 build() {
  23   cd ${srcdir}/${pkgname}-${pkgver}
  24
  25   patch -p0 < $srcdir/gnomebaker-0.6.4-libnotify-0.7.patch
  26
  27   ./configure \
  28     --prefix=/usr \
  29     --sysconfdir=/etc \
  30     --localstatedir=/var \
  31     --enable-libnotify
  32
  33   make LDFLAGS+="-Wl,--export-dynamic" || return 1
  34 }
  35
  36 package() {
  37   cd ${srcdir}/${pkgname}-${pkgver}
  38
  39   make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR=${pkgdir} install
  40
  41   mkdir -p ${pkgdir}/usr/share/gconf/schemas
  42   gconf-merge-schema \
  43     ${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas \
  44     ${pkgdir}/etc/gconf/schemas/*.schemas
  45   rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
  46 }
  47
  48 # vim:set ts=2 sw=2 et: