gpick-svn/PKGBUILD

   1 # Maintainer:  TDY <tdy@gmx.com>
   2 # Contributor: Loya Liu <loya.liu@gmail.com>
   3
   4 pkgname=gpick-svn
   5 pkgver=140
   6 pkgrel=1
   7 pkgdesc="An advanced color picker"
   8 arch=(i686 x86_64)
   9 url="http://gpick.googlecode.com/"
  10 license=('BSD')
  11 depends=('dbus-glib>=0.76' 'gtk2>=2.12.0' 'hicolor-icon-theme' 'lua>=5.1')
  12 makedepends=('boost' 'scons' 'subversion')
  13 provides=('gpick')
  14 conflicts=('gpick')
  15 install=gpick.install
  16 source=(gpick.desktop LICENSE)
  17 md5sums=('9bcf9591e2ff77dc34db093410aadb00'
  18          '8d148bfa61e38ba91b3a832dbb378320')
  19
  20 _svntrunk=http://gpick.googlecode.com/svn/trunk/
  21 _svnmod=gpick
  22
  23 build() {
  24   cd "$srcdir"
  25
  26   if [[ -d $_svnmod/.svn ]]; then
  27     cd $_svnmod && svn up -r $pkgver && cd ..
  28   else
  29     svn co $_svntrunk --config-dir ./ -r $pkgver $_svnmod
  30   fi
  31
  32   rm -rf $_svnmod-build
  33   cp -r $_svnmod $_svnmod-build
  34   cd $_svnmod-build
  35
  36   # quick patch for r140
  37   sed -i '19a\#include <cstddef>' source/Color{Action,List,Object}.cpp
  38
  39   scons
  40 }
  41
  42 package() {
  43   cd "$srcdir/$_svnmod-build"
  44   scons DESTDIR="$pkgdir/usr" install
  45   install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  46   install -Dm644 ../$_svnmod.desktop \
  47     "$pkgdir/usr/share/applications/$_svnmod.desktop"
  48 }