ettercap-gtk/PKGBUILD

   1 # $Id: PKGBUILD 103538 2010-12-21 10:37:25Z andrea $
   2 # Maintainer: Hugo Doria <hugo@archlinux.org>
   3 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   4
   5 pkgname=ettercap-gtk
   6 pkgver=NG_0.7.3
   7 _origname=ettercap
   8 _origver=NG-0.7.3
   9 pkgrel=8
  10 pkgdesc="A network sniffer/interceptor/logger for ethernet LANs - GTK"
  11 arch=('i686' 'x86_64')
  12 url="http://ettercap.sourceforge.net/"
  13 license=('GPL')
  14 depends=('ettercap' 'gtk2' 'libtool')
  15 makedepends=('libnet')
  16 options=('!libtool')
  17 source=(http://downloads.sourceforge.net/${_origname}/${_origname}-${_origver}.tar.gz
  18         'ettercap.desktop'
  19         'fix-segmentation-fault.patch')
  20 md5sums=('28fb15cd024162c55249888fe1b97820'
  21         '6ef18fdd114297d4ed9e5104d309f071'
  22         'e9cc99f13fd23edaba6cddffc4d0ef34')
  23
  24 build() {
  25   cd ${srcdir}/${_origname}-${_origver}
  26   unset LDFLAGS
  27
  28   # FS#21628
  29   patch -Np1 -i ${srcdir}/fix-segmentation-fault.patch
  30
  31   libtoolize --force --copy
  32   aclocal
  33   autoconf
  34   ./configure --prefix=/usr --sysconfdir=/etc --enable-plugins
  35   sed -i 's/LTDL_SHLIB_EXT/\".so\"/' src/ec_plugins.c
  36   make
  37 }
  38
  39 package() {
  40   install -Dm755 ${srcdir}/${_origname}-${_origver}/src/ettercap \
  41     ${pkgdir}/usr/bin/ettercap-gtk
  42   install -Dm644 ${srcdir}/ettercap.desktop \
  43     ${pkgdir}/usr/share/applications/ettercap.desktop
  44 }