fst-git/PKGBUILD

   1 # Maintainer: Ray Rashif <schivmeister@gmail.com>
   2
   3 pkgname=fst-git
   4 pkgver=20091102
   5 pkgrel=1
   6 pkgdesc="FreeST: Standalone wrapper for Windows VST plug-ins"
   7 arch=(i686)
   8 url="http://www.joebutton.co.uk/fst/"
   9 license=('GPL')
  10 depends=('lash' 'wine')
  11 makedepends=('git')
  12 provides=('fst')
  13 conflicts=('fst')
  14 install=fst-git.install
  15 source=()
  16 md5sums=()
  17
  18 _gitroot="git://repo.or.cz/fst.git"
  19 _gitname="fst"
  20
  21 build() {
  22   cd "$srcdir"
  23   msg "Connecting to GIT server...."
  24
  25   if [ -d $_gitname ] ; then
  26     (cd $_gitname && git pull origin)
  27     msg "The local files are updated."
  28   else
  29     git clone $_gitroot
  30   fi
  31
  32   msg "GIT checkout done or server timeout"
  33   msg "Starting make..."
  34
  35   cd $_gitname
  36   msg "Compiling..."
  37   make || return 1
  38
  39   # executable
  40   install -Dm755 fst.exe "$pkgdir/usr/bin/fst"
  41
  42   # libraries
  43   mkdir -p "$pkgdir/usr/lib/fst"
  44   install -m644 *.o "$pkgdir/usr/lib/fst/"
  45   install -m755 fst.exe.so "$pkgdir/usr/lib/libfst.so"
  46
  47   # header
  48   install -Dm644 fst.h "$pkgdir/usr/include/fst.h"
  49 }