lib32-freetype2-infinality/PKGBUILD

   1 # Maintainer: Shanto <shanto@hotmail.com>
   2 # Contributor: JIN Xiao-Yong <jinxiaoyong@gmail.com>
   3 # Contributor: Andre Fettouhi <A.Fettouhi@gmail.com>
   4
   5 _pkgbasename=freetype2-infinality
   6 pkgname=lib32-$_pkgbasename
   7 pkgver=2.4.8
   8 pkgrel=5
   9 _pkgdate=20111223
  10 _pkgrel=2
  11 pkgdesc="TrueType font rendering library (32-bit) with infinality patch"
  12 arch=(x86_64)
  13 license=('GPL')
  14 url="http://freetype.sourceforge.net"
  15 depends=('lib32-zlib' 'lib32-bzip2' $_pkgbasename)
  16 optdepends=(
  17         'lib32-libxft-lcd: LibXft with custom LCD filter'
  18 )
  19 makedepends=(gcc-multilib)
  20 conflicts=('lib32-freetype2')
  21 provides=("lib32-freetype2=$pkgver")
  22 options=('!libtool')
  23 source=(
  24         "http://downloads.sourceforge.net/sourceforge/freetype/freetype-${pkgver}.tar.bz2"
  25         "http://www.infinality.net/fedora/linux/zips/freetype-infinality-${pkgver}-${_pkgdate}_${_pkgrel}-x86_64.tar.bz2"
  26         "freetype-2.2.1-enable-valid.patch"
  27 )
  28 md5sums=(
  29         'dbf2caca1d3afd410a29217a9809d397'
  30         'd9925cbc99587399297982af341dc1e1'
  31         '214119610444c9b02766ccee5e220680'
  32 )
  33
  34 build() {
  35         export CC="gcc -m32"
  36         export CXX="g++ -m32"
  37         export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  38         rm -rf "${srcdir}/freetype-${pkgver}-build"
  39         cp -a "${srcdir}/freetype-${pkgver}" "${srcdir}/freetype-${pkgver}-build"
  40         cd "${srcdir}/freetype-${pkgver}-build"
  41         cat "$srcdir/freetype-"*.patch | patch -Np1
  42         ./configure --prefix=/usr --libdir=/usr/lib32
  43         make
  44 }
  45
  46 package() {
  47         cd "${srcdir}/freetype-${pkgver}-build"
  48         make DESTDIR="${pkgdir}" install
  49         rm -rf "${pkgdir}"/usr/{include,share,bin}
  50 }