lib32-cmt/PKGBUILD

   1 # Maintainer: josephgbr <rafael.f.f1 at gmail dot com>
   2 # Contributor:
   3
   4 _pkgbasename=cmt
   5 pkgname=lib32-$_pkgbasename
   6 pkgver=1.16
   7 pkgrel=2
   8 pkgdesc="CMT for LADSPA (32 bit)"
   9 arch=('x86_64')
  10 license=('GPL')
  11 url="http://www.ladspa.org"
  12 depends=('lib32-ladspa' 'lib32-gcc-libs')
  13 makedepends=('gcc-multilib')
  14 source=(http://www.ladspa.org/download/${_pkgbasename}_src_${pkgver}.tgz)
  15 md5sums=('15a875e5aaf79c209c223babfb41cb1c')
  16
  17 build() {
  18   cd "${srcdir}/${_pkgbasename}/src"
  19
  20   [ -f makefile-orig ] && mv makefile{-orig,} # allow rebuild
  21   # Fix directories and compiler flags for a lib32 package
  22   sed -i-orig \
  23         -e '/INSTALL_PLUGINS_DIR/s/lib/&32/' \
  24         -e 's|^CFLAGS|CXX\t\t\=\tg++ -m32\nCFLAGS|g' \
  25         -e "/CFLAGS/ s/-O3/${CFLAGS}/" \
  26         -e 's|-Werror||g' \
  27         makefile
  28   make
  29 }
  30
  31 package() {
  32   cd "${srcdir}/${_pkgbasename}/src"
  33   install -d -m755 "${pkgdir}/usr/lib32/ladspa/"
  34   install -m755 ../plugins/cmt.so "${pkgdir}/usr/lib32/ladspa/"
  35 }