mythtv-0-23-fixes-svn/PKGBUILD

   1 # Maintainer: leprechau <ahurt@anbcs.com>
   2 # Contributer: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Juergen Hoetzel <juergen@archlinux.org>
   4 # Contributor: <kleptophobiac@gmail.com>
   5 # Contributor: dorphell <dorphell@archlinux.org>
   6
   7 pkgname=mythtv-0-23-fixes-svn
   8 pkgver=24836
   9 pkgrel=1
  10 pkgdesc="A Homebrew PVR project"
  11 arch=('i686' 'x86_64')
  12 url="http://www.mythtv.org/"
  13 license=('GPL')
  14 depends=('mysql-clients' 'qt' 'lame' 'lirc-utils' 'ffmpeg' 'libxvmc' 'fribidi'
  15          'perl-soap-lite' 'perl-date-manip' 'perl-xml-sax' 'perl-math-round'
  16          'perl-net-upnp' 'perl-dbd-mysql' 'perl-time-hires' 'libavc1394' 'wget'
  17          'libiec61883' 'mysql-python' 'mesa' 'libxinerama' 'libxrandr' 'yasm')
  18 makedepends=('subversion')
  19 optdepends=('xmltv: to download tv listings')
  20 replaces=('mythtv-contrib' 'mythtv')
  21 conflicts=('mythtv-contrib' 'mythtv')
  22 provides=('mythtv')
  23 backup=('etc/conf.d/mythbackend')
  24 install=mythtv.install
  25 source=('mythbackend' 'archlinux.conf.d.mythbackend')
  26 md5sums=('feadcc9ad064d93d6dceab1efc0bd9ed'
  27          'bb8e4033d82428d827570fae9ba15e6a')
  28
  29 _svntrunk=http://code.mythtv.org/svn/branches/release-0-23-fixes/mythtv
  30 _svnmod=${pkgname}
  31
  32 build() {
  33   cd "${srcdir}"
  34
  35   if [ -d ${_svnmod}/.svn ]; then
  36     (cd ${_svnmod} && svn up)
  37   else
  38     svn co ${_svntrunk} --config-dir ./ ${_svnmod}
  39   fi
  40
  41   ARCH=${CARCH/_/-}
  42
  43   msg "SVN checkout complete or server timeout"
  44   msg "Starting configure and make..."
  45
  46   rm -rf "${srcdir}/${_svnmod}-build"
  47   cp -r "${srcdir}/${_svnmod}" "${srcdir}/${_svnmod}-build"
  48   cd "${srcdir}/${_svnmod}-build"
  49
  50   ./configure --prefix=/usr --cpu=${ARCH} \
  51               --enable-mmx \
  52               --enable-audio-oss \
  53               --enable-audio-alsa \
  54               --disable-audio-jack \
  55               --disable-audio-pulse \
  56               --disable-altivec \
  57               --disable-distcc \
  58               --disable-ccache \
  59               --enable-ffmpeg \
  60               --enable-vdpau \
  61               --enable-libfaad \
  62               --enable-glx-procaddrarb \
  63               --enable-dvb \
  64               --enable-lirc \
  65               --enable-joystick-menu \
  66               --enable-v4l \
  67               --enable-ivtv \
  68               --enable-dvb \
  69               --dvb-path=/usr/include \
  70               --enable-xvmc \
  71               --enable-xvmcw \
  72               --enable-xvmc-pro \
  73               --enable-xvmc-vld \
  74               --enable-firewire \
  75               --enable-fribidi \
  76               --enable-opengl-vsync \
  77               --enable-xrandr \
  78               --enable-xv \
  79               --enable-x11 \
  80               --with-bindings=perl,python
  81
  82   qmake mythtv.pro
  83   make all || return 1
  84   # basic install
  85   make INSTALL_ROOT="${pkgdir}" install || return 1
  86   install -D -m0755 ${srcdir}/mythbackend "${pkgdir}/etc/rc.d/mythbackend" || return 1
  87   # config file
  88   install -D -m644 ${srcdir}/archlinux.conf.d.mythbackend "${pkgdir}/etc/conf.d/mythbackend" || return 1
  89   # install contrib files
  90   cp -a contrib/$i ${pkgdir}/usr/share/mythtv
  91   # install database structure
  92   cd database
  93   cp -a mc.sql ${pkgdir}/usr/share/mythtv
  94 }