pcsx2-bin/PKGBUILD

   1 # Maintainer: josephgbr <rafael.f.f1 at gmail dot com>
   2 # Contributor:
   3
   4 pkgname=pcsx2-bin
   5 pkgver=0.9.8
   6 pkgrel=3
   7 _pkgrev=r4594
   8 _extrainfo=-linux~translation_fix
   9 pkgdesc="A PlayStation 2 emulator."
  10 arch=('i686' 'x86_64')
  11 url="http://www.pcsx2.net"
  12 license=('GPL')
  13 if [ $CARCH == "x86_64" ]; then
  14         depends=('lib32-alsa-lib' 'lib32-bzip2' 'lib32-glew1.5'
  15                  'lib32-libjpeg6' 'lib32-nvidia-cg-toolkit'
  16                  'lib32-portaudio' 'lib32-sdl' 'lib32-wxgtk'
  17                  'lib32-zlib')
  18 else
  19         depends=('alsa-lib' 'bzip2' 'glew1.5' 'libjpeg6'
  20                  'nvidia-cg-toolkit' 'portaudio' 'sdl'
  21                  'wxgtk' 'zlib')
  22 fi
  23 provides=('pcsx2')
  24 conflicts=('pcsx2' 'pcsx2-svn')
  25 options=('!emptydirs')
  26 install="pcsx2.install"
  27 source=("http://pcsx2.googlecode.com/files/pcsx2-$pkgver-${_pkgrev}${_extrainfo}.tar.gz"
  28         'pcsx2.sh' 'pcsx2.xpm' 'pcsx2.desktop')
  29 md5sums=('7441387fd223827248c23727d5bc87c7'
  30          'c3f5a0dc776362db1950c8b0eb4c0a69'
  31          '18cb3c5a243a27363553d3e1008210c0'
  32          'b055ff7c0f236f33702f4813ae4b980d')
  33
  34 package() {
  35         cd "${srcdir}/pcsx2-$pkgver-$_pkgrev-linux"
  36
  37         mkdir -p "${pkgdir}/opt/pcsx2" \
  38                         "${pkgdir}/usr/share/man/man1" \
  39                         "${pkgdir}/usr/share/locale"
  40         # Install PCSX2
  41         cp -rPf * "${pkgdir}/opt/pcsx2/"
  42         # Install translation files
  43         mv "${pkgdir}/opt/pcsx2/Langs/"* \
  44                 "${pkgdir}/usr/share/locale/"
  45         # Install man page
  46         mv "${pkgdir}/opt/pcsx2/docs/pcsx2.man" \
  47                 "${pkgdir}/usr/share/man/man1/pcsx2.1"
  48         # Install runnable script, icon and desktop item
  49         install -Dm755 "${srcdir}/pcsx2.sh" \
  50                         "${pkgdir}/usr/bin/pcsx2"
  51         install -Dm644 "${srcdir}/pcsx2.xpm" \
  52                         "${pkgdir}/usr/share/pixmaps/pcsx2.xpm"
  53         install -Dm644 "${srcdir}/pcsx2.desktop" \
  54                         "${pkgdir}/usr/share/applications/pcsx2.desktop"
  55         # Removing uneeded stuff / cleanup
  56         rmdir "${pkgdir}/opt/pcsx2/"{Langs,bios,help}
  57         rm "${pkgdir}/opt/pcsx2/launch_pcsx2_linux.sh"
  58 }