exaile-bzr/PKGBUILD

   1 # Maintainer: Alessio Sergi <asergi at archlinux dot us>
   2 # Contributor: Aren Olson <reacocard at gmail dot com>
   3
   4 pkgname=exaile-bzr
   5 _pkgname=exaile
   6 pkgver=3905
   7 pkgrel=1
   8 pkgdesc="A full featured music player written for GTK+"
   9 arch=('any')
  10 url="https://launchpad.net/exaile"
  11 license=('GPL2' 'GPL3')
  12 depends=('dbus-python' 'desktop-file-utils' 'gstreamer0.10-good-plugins' \
  13          'gstreamer0.10-python' 'mutagen' 'pygtk' 'python2-bsddb')
  14 makedepends=('bzr' 'help2man')
  15 optdepends=('exfalso: ex-falso tag editor'
  16             'gstreamer0.10-plugins: more codecs'
  17             'hal: device autodetection'
  18             'ipython: ipython plugin'
  19             'libgpod: iPod support'
  20             'moodbar: moodbar plugin'
  21             'notify-osd: notify-osd notifications'
  22             'pybonjour: DAAP server plugin'
  23             'pycddb: CD metadata retrieval'
  24             'python-notify: libnotify notifications'
  25             'python-imaging: contextinfo plugin'
  26             'python2-mmkeys: xkeys plugin'
  27             'pywebkitgtk: contextinfo plugin'
  28             'streamripper: streamripper plugin')
  29 provides=(${_pkgname})
  30 conflicts=(${_pkgname} ${_pkgname}-beta ${_pkgname}-old)
  31 install=${pkgname}.install
  32
  33 _bzrtrunk="lp:${_pkgname}"
  34 _bzrmod="${_pkgname}"
  35
  36 build() {
  37   cd "${srcdir}"
  38
  39   msg "Connecting to the server...."
  40
  41   if [ -d ${_bzrmod} ]; then
  42     bzr up ${_bzrmod}
  43     msg "The local files are updated."
  44   else
  45     bzr co ${_bzrtrunk} ${_bzrmod}
  46   fi
  47
  48   msg "BZR checkout done or server timeout"
  49   msg "Starting make..."
  50
  51   rm -rf "${_bzrmod}-build"
  52   cp -r "${_bzrmod}" "${_bzrmod}-build"
  53   cd "${_bzrmod}-build"
  54
  55   # python2 fix
  56   for file in plugins/*/*.py; do
  57     sed -i 's_python_&2_' "${file}"
  58   done
  59
  60   make
  61 }
  62
  63 package() {
  64   cd "${srcdir}/${_bzrmod}-build"
  65
  66   make PREFIX=/usr DESTDIR="${pkgdir}" install
  67 }
  68
  69 # vim:set ts=2 sw=2 et: