netkit-bsd-finger-ipv6/PKGBUILD

   1 # Contributor: <grawity@gmail.com>
   2 pkgname=netkit-bsd-finger-ipv6
   3 pkgver=0.17
   4 pkgrel=8
   5 pkgdesc="bsd-finger ported to Linux, with IPv6 and other Debian patches"
   6 arch=('i686' 'x86_64')
   7 url="ftp://ftp.uk.linux.org/pub/linux/Networking/netkit"
   8 license=('BSD')
   9 depends=('glibc')
  10 provides=('netkit-bsd-finger')
  11 conflicts=('netkit-bsd-finger')
  12 backup=('etc/xinetd.d/finger')
  13 source=(
  14         "ftp://ftp.uk.linux.org/pub/linux/Networking/netkit/bsd-finger-$pkgver.tar.gz"
  15         "http://ftp.de.debian.org/debian/pool/main/b/bsd-finger/bsd-finger_0.17-14.debian.tar.bz2"
  16         "finger.xinetd"
  17         "systemd-fingerd.socket"
  18         "systemd-fingerd@.service"
  19         "LICENSE")
  20 md5sums=('52bf281aac8814bf56cdc92f7661ee75'
  21          '21bf0e0d52d7e186cdc8edceafab99f0'
  22          '5929b923276d38139aeb3305116980ed'
  23          'ac34ebab3a412eca1bf5a93b88249b8c'
  24          '823f0ea1c43deeb34e786fdf63db8368'
  25          '5fc568418a0379fc3a358ed1c2523b44')
  26
  27 build() {
  28         cd "$srcdir/bsd-finger-$pkgver"
  29
  30         while read -r file; do
  31                  patch -p1 < "../debian/patches/$file"
  32         done < "../debian/patches/series"
  33
  34         sed -i 's@include <sys/time.h>@include <time.h>@' finger/lprint.c
  35         sed -i 's@include <sys/time.h>@include <time.h>@' finger/sprint.c
  36
  37         ./configure --prefix=/usr
  38         make
  39 }
  40
  41 package() {
  42         cd "$srcdir/bsd-finger-$pkgver"
  43         install -d "$pkgdir"/usr/{bin,sbin} "$pkgdir"/usr/share/man/{man1,man8}
  44         make INSTALLROOT="$pkgdir" MANDIR=/usr/share/man install
  45
  46         install -D -m644 "$srcdir/finger.xinetd" "$pkgdir/etc/xinetd.d/finger"
  47         install -D -m644 "$srcdir/systemd-fingerd.socket" \
  48                 "$pkgdir/lib/systemd/system/fingerd.socket"
  49         install -D -m644 "$srcdir/systemd-fingerd@.service" \
  50                 "$pkgdir/lib/systemd/system/fingerd@.service"
  51
  52         install -D -m644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  53 }