fluxbox-git/PKGBUILD

   1 # Maintainer:  Devin Cofer <ranguvar{AT]archlinux[DOT}us>
   2 # Contributor: Cainã Costa <sryche@archlinux-br.org>
   3 # Contributor: Patrick Bartels <p4ddy.b@gmail.com>
   4
   5 pkgname=fluxbox-git
   6 _pkgname=fluxbox
   7 pkgdesc="Lightweight stacking WM with tabbing, dockapps, etc. (Dev version)"
   8 pkgver=20091012
   9 pkgrel=1
  10 arch=('i686' 'x86_64')
  11 license=('MIT')
  12 url="http://www.fluxbox.org/"
  13
  14 makedepends=('git' 'pkgconfig')
  15 depends=('libxft' 'libxpm' 'libxrandr' 'imlib2' 'libxinerama')
  16 conflicts=('fluxbox')
  17 provides=('fluxbox')
  18
  19 source=("$_pkgname.desktop")
  20 sha256sums=('e1e6cc6a7e55df1981ff5df1bd345221e657ed68ac12583553b951e454695d67')
  21
  22 backup=('usr/bin/startfluxbox')
  23
  24 _gitroot="git://git.fluxbox.org/fluxbox.git"
  25 _gitname="fluxbox"
  26
  27
  28 options=('!libtool')
  29 build() {
  30         cd "$srcdir"
  31         msg "Performing source checkout..."
  32         if [ -d "$_gitname" ]; then
  33                 cd "$_gitname"
  34                 git pull origin || return 1
  35                 cd ..
  36         else
  37                 git clone "$_gitroot" || return 1
  38         fi
  39         msg "Source checkout finished."
  40         rm -rf "$_gitname-build"
  41         git clone "$_gitname" "$_gitname-build" || return 1
  42         cd "$_gitname-build"
  43
  44         ./autogen.sh || return 1
  45         ./configure --prefix=/usr --enable-xft --enable-imlib2 --enable-nls \
  46                     --enable-xinerama --enable-gnome || return 1
  47         make || return 1
  48 }
  49 package() {
  50         cd "$srcdir/$_gitname-build"
  51
  52         make DESTDIR="$pkgdir" install || return 1
  53
  54         install -Dm644 "$srcdir/$_pkgname.desktop" \
  55                        "$pkgdir/etc/X11/sessions/$_pkgname.desktop" || return 1
  56         install -Dm644 COPYING "$pkgdir/usr/share/licenses/$_pkgname/COPYING" || return 1
  57 }