lirc-utils-git/PKGBUILD

   1 # Maintainer: Mark Foxwell <fastfret79@archlinux.org.uk>
   2
   3 pkgname=('lirc-utils-git')
   4 pkgver=20110524
   5 pkgrel=1
   6 _kernver=2.6.39-ARCH
   7 pkgdesc="Linux Infrared Remote Control utils"
   8 depends=('alsa-lib' 'libx11' 'libftdi' 'libirman')
   9 optdepends=('python2: pronto2lirc utility')
  10 options=('strip' '!libtool')
  11 arch=('i686' 'x86_64')
  12 url="http://www.lirc.org/"
  13 license=('GPL')
  14 makedepends=('help2man' 'kernel26-headers' 'alsa-lib' 'libx11' 'libftdi' 'libirman' 'python2' 'git')
  15 source=(irexec.conf lirc.logrotate lircd.conf lircd lircmd irexecd)
  16 provides=lirc-utils
  17 conflicts=lirc-utils
  18 md5sums=('f0c0ac930326168035f0c8e24357ae55'
  19          '3deb02604b37811d41816e9b4385fcc3'
  20          '5b1f8c9cd788a39a6283f93302ce5c6e'
  21          '8d0e238dc0eda95e340fe570605da492'
  22          '85f7fdac55e5256967241864049bf5e9'
  23          '69d099e6deedfa3c1ee2b6e82d9b8bfb')
  24
  25 _gitroot="git://lirc.git.sourceforge.net/gitroot/lirc/lirc"
  26 _gitname="lirc"
  27
  28 build() {
  29   cd "$srcdir"
  30   msg "Connecting to GIT server...."
  31
  32   if [ -d $_gitname ] ; then
  33     cd $_gitname && git pull origin
  34     msg "The local files are updated."
  35   else
  36     git clone $_gitroot $_gitname
  37   fi
  38
  39   msg "GIT checkout done or server timeout"
  40   msg "Starting make..."
  41
  42   rm -rf "$srcdir/$_gitname-build"
  43   git clone "$srcdir/$_gitname" "$srcdir/$_gitname-build"
  44   cd "$srcdir/$_gitname-build"
  45
  46   sed -i '/AC_PATH_XTRA/d' configure.ac
  47   sed -e 's/@X_CFLAGS@//g' \
  48       -e 's/@X_LIBS@//g' \
  49       -e 's/@X_PRE_LIBS@//g' \
  50       -e 's/@X_EXTRA_LIBS@//g' -i Makefile.am tools/Makefile.am
  51
  52   ./autogen.sh
  53   PYTHON=/usr/bin/python2  ./configure --enable-sandboxed --prefix=/usr \
  54           --with-driver=all --with-kerneldir=/usr/src/linux-${_kernver}/ \
  55           --with-moduledir=/lib/modules/${_kernver}/kernel/drivers/misc \
  56           --with-transmitter
  57
  58   # Remove drivers already in kernel
  59   sed -e "s:lirc_dev::" -e "s:lirc_bt829::" -e "s:lirc_igorplugusb::" \
  60       -e "s:lirc_imon::" -e "s:lirc_parallel::" -e "s:lirc_sasem::" \
  61       -e "s:lirc_serial::" -e "s:lirc_sir::" -e "s:lirc_ttusbir::" \
  62       -e "s:lirc_atiusb::" -e "s:lirc_i2c::" -e "s:lirc_wpc8769l::" \
  63       -i Makefile drivers/Makefile drivers/*/Makefile tools/Makefile
  64
  65   make
  66 }
  67
  68 package() {
  69
  70   cd "$srcdir/$_gitname-build"
  71
  72   make DESTDIR="${pkgdir}" install
  73
  74   install -d "${pkgdir}/usr/share/lirc" "${pkgdir}/etc/rc.d"
  75   cp "${srcdir}"/{lircd,lircmd,irexecd} "${pkgdir}/etc/rc.d"
  76   cp -rp remotes "${pkgdir}/usr/share/lirc"
  77   chmod -R go-w "${pkgdir}/usr/share/lirc/"
  78
  79   # install the logrotate config
  80   install -Dm644 "${srcdir}/lirc.logrotate" "${pkgdir}/etc/logrotate.d/lirc"
  81
  82   # install conf.d file
  83   install -Dm644 "${srcdir}/lircd.conf" "${pkgdir}/etc/conf.d/lircd.conf"
  84
  85   # install conf.d file
  86   install -Dm644 "${srcdir}/irexec.conf" "${pkgdir}/etc/conf.d/irexec.conf"
  87
  88   install -d "${pkgdir}/etc/lirc"
  89
  90 }
  91
  92 # vim:set ts=2 sw=2 et: