foobar2000/PKGBUILD

   1 # Maintainer: Florian Léger <florian6 dot leger at laposte dot net>
   2 pkgname=foobar2000
   3 pkgver=1.1.10
   4 pkgrel=1
   5 pkgdesc="An advanced freeware audio player (uses Wine)."
   6 arch=(i686 x86_64)
   7 url="http://www.foobar2000.org/"
   8 license=('custom')
   9 depends=(wine desktop-file-utils)
  10 makedepends=(p7zip)
  11 source=("http://www.freecodecs.net/fc/foobar2000_${pkgver}.zip"
  12         "LICENSE"
  13         "${pkgname}.sh"
  14         "http://upload.wikimedia.org/wikipedia/en/f/f9/Foobar2000_Icon.png"
  15         "${pkgname}.desktop")
  16 install="${pkgname}.install"
  17 md5sums=('7e8c45a2daa059d5dee739f3d4fcdfaa'
  18          '91873c4c3115bdd1afcf52c3023dc896'
  19          '63f65a22001873c7b765e06f6c66707f'
  20          '927c185d2f680b44faf1a47f528905c7'
  21          '138cb528cb0cad4e2764c3c77555369c')
  22
  23 package() {
  24   # Set up the environment
  25   local tmpdir="${srcdir}/foobar2000"
  26   local -A files
  27
  28   files=( ["/"]="foobar2000*.exe *.html *.css zlib1.dll shared.dll"
  29     ["components"]="foo_*.dll"
  30     ["icons"]="*.ico"
  31     ["themes"]="*.fth"
  32   )
  33
  34   local f
  35   local d
  36
  37   mkdir -p "${tmpdir}"
  38
  39   # Extract foobar (7z x gives garbage)
  40   7z e -y -o"${tmpdir}" "${srcdir}/${pkgname}_v${pkgver}.exe"
  41
  42   # Installation
  43   cd "${tmpdir}"
  44   for d in "${!files[@]}"; do
  45     for f in ${files[$d]}; do
  46       install -Dm644 "${tmpdir}/${f}" "${pkgdir}/usr/share/${pkgname}/${d}/${f}"
  47     done
  48   done
  49
  50   # Install the license
  51   install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  52
  53   # Install the script
  54   install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
  55
  56   # Install the icon
  57   install -Dm644 "${srcdir}/Foobar2000_Icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  58
  59   # Install the .desktop
  60   install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  61 }