lib32-libgphoto2/PKGBUILD

   1 # Maintainer: josephgbr <rafael.f.f1@gmail.com>
   2
   3 _pkgbase=libgphoto2
   4 pkgname=lib32-$_pkgbase
   5 pkgver=2.4.11
   6 pkgrel=1
   7 pkgdesc="The core library of gphoto2, designed to allow access to digital camera by external programs. (32 bit)"
   8 arch=('x86_64')
   9 url="http://www.gphoto.org"
  10 license=(LGPL)
  11 depends=('lib32-libexif' 'lib32-libjpeg-turbo' 'lib32-gd'
  12          'lib32-libltdl' 'lib32-libusb-compat')
  13 makedepends=('gcc-multilib')
  14 options=('!libtool')
  15 source=(http://downloads.sourceforge.net/gphoto/${_pkgbase}-${pkgver}.tar.gz)
  16 md5sums=('a2230c31e320acb7ececd90bc02fe515')
  17
  18 build() {
  19   export CC='gcc -m32'
  20   export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  21
  22   cd "${srcdir}/${_pkgbase}-${pkgver}"
  23   udevscriptdir=/lib/udev ./configure --prefix=/usr --with-drivers=all \
  24         --disable-static --disable-rpath --libdir=/usr/lib32
  25   make
  26 }
  27
  28 package() {
  29   cd "${srcdir}/${_pkgbase}-${pkgver}"
  30   make DESTDIR="${pkgdir}" install
  31   rm -rf "${pkgdir}"/{lib,usr/{bin,include,share}}
  32 }