mmex-svn/PKGBUILD

   1 # Maintainer: TDY <tdy@gmx.com>
   2
   3 pkgname=mmex-svn
   4 pkgver=882
   5 pkgrel=1
   6 pkgdesc="An easy-to-use personal finance suite (Money Manager Ex)"
   7 arch=('i686' 'x86_64')
   8 url="http://www.codelathe.com/mmex/"
   9 license=('GPL')
  10 depends=('wxgtk>=2.8.10')
  11 makedepends=('boost' 'gettext' 'subversion')
  12 optdepends=('cups: for printing support')
  13 provides=('mmex')
  14 conflicts=('mmex')
  15 install=mmex.install
  16 source=(mmex.desktop)
  17 md5sums=('ac08bedafef42de7946353fff8da8a7c')
  18
  19 _svntrunk=http://moneymanagerex.svn.sourceforge.net/svnroot/moneymanagerex
  20 _svnmod=mmex
  21
  22 build() {
  23   cd "$srcdir"
  24
  25   msg "Connecting to $_svntrunk..."
  26   if [[ -d $_svnmod/.svn ]]; then
  27     cd $_svnmod && svn up -r $pkgver && cd ..
  28     msg2 "Local files updated"
  29   else
  30     svn co $_svntrunk --config-dir ./ -r $pkgver $_svnmod
  31     msg2 "SVN checkout done"
  32   fi
  33
  34   rm -rf $_svnmod/trunk/$_svnmod-build
  35   cp -r $_svnmod/trunk/$_svnmod $_svnmod/trunk/$_svnmod-build
  36   install -dm755 $_svnmod/trunk/$_svnmod-build/wxbuild
  37   cd $_svnmod/trunk/$_svnmod-build/wxbuild
  38
  39   msg "Starting make..."
  40   ../configure --prefix=/usr \
  41       --enable-unicode \
  42       --enable-shared \
  43       --with-wxshared \
  44       --with-gtk \
  45       --with-wx-config=/usr/lib/wx/config/gtk2-unicode-release-2.8
  46   make || return 1
  47 }
  48
  49 package() {
  50   cd "$srcdir/$_svnmod/trunk/$_svnmod-build/wxbuild"
  51   make DESTDIR="$pkgdir" install
  52   install -Dm644 "$srcdir/mmex.desktop" \
  53     "$pkgdir/usr/share/applications/mmex.desktop"
  54   install -Dm644 ../graphics/mmexlogo.png "$pkgdir/usr/share/pixmaps/mmex.png"
  55 }