rainbowcrack/PKGBUILD

   1 # Maintainer: SpepS <dreamspepser at yahoo dot it>
   2 # Contributor: Geoffroy Carrier <geoffroy.carrier@koon.fr>
   3 # Contributor: Michal Krenek <mikos@sg1.cz>
   4
   5 pkgname=rainbowcrack
   6 pkgver=1.2
   7 pkgrel=4
   8 pkgdesc="Password cracker based on the faster time-memory trade-off. With MySQL and Cisco PIX Algorithm patches"
   9 arch=('i686' 'x86_64')
  10 url="http://project-rainbowcrack.com/"
  11 license=('custom')
  12 depends=('openssl')
  13 source=("$pkgname-$pkgver-src.tar.xz"
  14         "http://www.oxid.it/downloads/rc_patch_mysql_pix.zip")
  15 md5sums=('60137c06b727d6d3ca50340ff2c68292'
  16          '71845ac352ff888a9cfcff6c1ea4184b')
  17
  18 build() {
  19   cd "$srcdir/$pkgname-$pkgver-src/src"
  20
  21   # MySQL and Cisco PIX Algorithm patches
  22   install -Dm644 ${srcdir}/*.{h,cpp} .
  23
  24   # missing headers
  25   sed -i "11i#include <stdlib.h>\n#include <string.h>" Public.h
  26
  27   # DSO link fix for crypto
  28   sed -i "s/-lssl/& -lcrypto/" makefile.linux
  29
  30   make -f makefile.linux
  31 }
  32
  33 package() {
  34   cd "$srcdir/$pkgname-$pkgver-src/src"
  35
  36   # bin
  37   install -d "$pkgdir/usr/bin"
  38   install -Dm755 r{t,c}* "$pkgdir/usr/bin"
  39
  40   # data
  41   install -Dm644 "$srcdir/readme.txt" \
  42     "$pkgdir/usr/share/$pkgname/patches.txt"
  43   install -Dm644 charset.txt ../readme.txt \
  44     "$pkgdir/usr/share/$pkgname"
  45
  46   # docs
  47   install -d "$pkgdir/usr/share/doc/$pkgname"
  48   install -Dm644 ../doc/* \
  49     "$pkgdir/usr/share/doc/$pkgname"
  50
  51   # license
  52   install -Dm644 ../disclaimer.txt \
  53     "$pkgdir/usr/share/licenses/$pkgname/LICENCE"
  54 }