selinux-refpolicy/PKGBUILD

   1 # Maintainer: Nicky726 (Nicky726 <at> gmail <dot> com)
   2 # Contributor: Simon Peter Nicholls (simon <at> mintsource <dot> org)
   3
   4 pkgname=selinux-refpolicy
   5 _origname=refpolicy
   6 _policyname=refpolicy
   7 pkgver=20110726
   8 pkgrel=3
   9 pkgdesc="Modular SELinux reference policy including headers and docs"
  10 arch=('any')
  11 url="http://oss.tresys.com/projects/refpolicy"
  12 license=('GPL')
  13 groups=('selinux' 'selinux-policies')
  14 depends=('linux-selinux')
  15 makedepends=('selinux-usr-checkpolicy>=2.0.16' 'selinux-usr-policycoreutils>=2.0.0'
  16              'selinux-usr-libsepol>=2.0.29' 'selinux-usr-libsemanage>=2.0.29'
  17              'pyxml')
  18 conflicts=('selinux-refpolicy-arch')
  19 backup=(etc/selinux/config)
  20 options=(!makeflags)
  21 install=${pkgname}.install
  22 source=(http://oss.tresys.com/files/${_origname}/${_origname}-2.${pkgver}.tar.bz2
  23         config)
  24 sha256sums=('8159b7535aa0f805510e4e3504b1317d7083b227f0ef3df51c6f002ed70ecedb'
  25             '3f0d87faaffbae4d8ffde92de6e56309726f53c8a083460c92d2f1d2dccf525d')
  26
  27 build() {
  28   cd "${srcdir}/${_origname}"
  29   # Policy build settings
  30   sed -i -e "s/MONOLITHIC = y/MONOLITHIC = n/" build.conf
  31   sed -i -e "s/#UNK_PERMS = deny/UNK_PERMS = allow/" build.conf
  32   sed -i -e "s/DIRECT_INITRC = n/DIRECT_INITRC = y/" build.conf
  33   sed -i -e "s/UBAC = y/UBAC = n/" build.conf
  34   # Fix for python2
  35   sed -i -e "s/python/python2/" Makefile
  36   make bare
  37   make conf
  38   make
  39 }
  40
  41 package(){
  42   cd "${srcdir}/${_origname}"
  43   make DESTDIR="${pkgdir}" install
  44   make DESTDIR="${pkgdir}" install-headers
  45   make DESTDIR="${pkgdir}" install-docs
  46
  47   # Create some files and directories necesary for loading policy,
  48   # which is done via install script.
  49   install -d -m0755 "${pkgdir}/etc/selinux/${_policyname}/modules"
  50   install -d -m0700 "${pkgdir}/etc/selinux/${_policyname}/modules/active"
  51   install -d -m0700 "${pkgdir}/etc/selinux/${_policyname}/modules/active/modules"
  52   install -d -m0755 "${pkgdir}/etc/selinux/${_policyname}/policy"
  53   touch "${pkgdir}/etc/selinux/${_policyname}/modules/"{semanage.read.LOCK,semanage.trans.LOCK}
  54   touch "${pkgdir}/etc/selinux/${_policyname}/policy/policy.26"
  55   # Link the policy file for selinux-sysvinit to find it
  56   cd "${pkgdir}/etc"
  57   ln -s "selinux/${_policyname}/policy/policy.26" "policy.bin"
  58
  59   # Install main SELinux config file defaulting to refpolicy
  60   install -m644 -D "${srcdir}/config" "${pkgdir}/etc/selinux/config"
  61
  62   # Some changes due to python2
  63   sed -i -e "s/python/python2/" \
  64         "${pkgdir}/usr/share/selinux/${_policyname}/include/support/segenxml.py"
  65   sed -i -e "s/python/python2/" \
  66         "${pkgdir}/usr/share/selinux/${_policyname}/include/Makefile"
  67 }