lib32-orc/PKGBUILD

   1 # Maintainer: SpepS <dreamspepser at yahoo dot it>
   2
   3 _pkg=orc
   4 pkgname=lib32-$_pkg
   5 pkgver=0.4.14
   6 pkgrel=1
   7 pkgdesc="The Oild Runtime Compiler. Multilib"
   8 arch=('x86_64')
   9 license=('custom')
  10 url="http://code.entropywave.com/projects/orc/"
  11 depends=('lib32-glibc' "$_pkg")
  12 makedepends=('gcc-multilib')
  13 options=('!libtool')
  14 source=("http://code.entropywave.com/download/$_pkg/$_pkg-$pkgver.tar.gz")
  15 md5sums=('6b3ff209e9763ebe40e152538884bd71')
  16
  17 build() {
  18   cd "$srcdir/$_pkg-$pkgver"
  19
  20   # multilib
  21   export CC='gcc -m32'
  22   export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  23
  24   ./configure --prefix=/usr \
  25               --libdir=/usr/lib32 \
  26               --disable-static
  27   make
  28 }
  29
  30 package() {
  31   cd "$srcdir/$_pkg-$pkgver"
  32
  33   make DESTDIR="$pkgdir/" install
  34
  35   # Removing unneeded files
  36   rm -rf "$pkgdir"/usr/{bin,include,share}
  37
  38   # license
  39   install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  40 }