gtk3-git/PKGBUILD

   1 # Maintainer: RKA KriK <rka_krik@mail.ru>
   2
   3 pkgname=gtk3-git
   4 pkgver=20110824
   5 pkgrel=2
   6 _realver=3.1.12
   7 pkgdesc="The GTK+ Toolkit (v3.1.x, unstable, with wayland support)"
   8 arch=('i686' 'x86_64')
   9 url="http://www.gtk.org/"
  10 install=gtk3.install
  11 depends=('glib2-git' 'atk' 'cairo' 'gtk-update-icon-cache' 'libcups' 'libxcursor'
  12                 'libxinerama' 'libxrandr' 'libxi' 'libxcomposite' 'libxdamage'
  13                 'shared-mime-info' 'libxkbcommon-git' 'pango-unstable')
  14 makedepends=('gobject-introspection')
  15 conflicts=('gtk3')
  16 provides=("gtk3=${_realver}")
  17 options=('!libtool' '!docs')
  18 backup=(etc/gtk-3.0/settings.ini)
  19 license=('LGPL')
  20 source=(settings.ini)
  21 sha256sums=('3f2fd1ac4e0a59381e443b7c14d937b434c515e02d06c7c4b3999fb24406b784')
  22
  23 _gitroot="git://git.gnome.org/gtk+"
  24 _gitname="gtk+"
  25
  26 build() {
  27   msg "Connecting to gnome.org GIT server...."
  28
  29   if [ -d ${srcdir}/${_gitname} ] ; then
  30     cd ${_gitname} && git pull origin
  31     msg "The local files are updated."
  32   else
  33     git clone ${_gitroot}
  34   fi
  35
  36   msg "GIT checkout done or server timeout"
  37   msg "Creating build directory"
  38   if [ -d ${srcdir}/${_gitname}-build ]; then rm -rf ${srcdir}/${_gitname}-build; fi
  39   cp -R ${srcdir}/${_gitname} ${srcdir}/${_gitname}-build
  40
  41   msg "Starting make..."
  42
  43   cd ${srcdir}/${_gitname}-build
  44   CXX=/bin/false ./autogen.sh --prefix=/usr --sysconfdir=/etc \
  45                 --localstatedir=/var --enable-gtk2-dependency \
  46                 --enable-x11-backend --enable-wayland-backend \
  47                 --disable-schemas-compile #--disable-glibtest
  48
  49   #https://bugzilla.gnome.org/show_bug.cgi?id=655517
  50   #sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  51   make
  52 }
  53
  54 package() {
  55   cd ${srcdir}/${_gitname}-build
  56   make DESTDIR="${pkgdir}" install
  57
  58   install -Dm644 "${srcdir}/settings.ini" "${pkgdir}/etc/gtk-3.0/settings.ini"
  59 }