fuse4j-git/PKGBUILD

   1 # Maintainer: Julien Nicoulaud <julien.nicoulaud@gmail.com>
   2 # Source: https://github.com/nicoulaj/archlinux-packages
   3 pkgname=fuse4j-git
   4 _pkgname=fuse4j
   5 pkgver=20120115
   6 pkgrel=1
   7 pkgdesc="Re-factor of Fuse-J to support Mac OS X and fork into the background."
   8 arch=(x86 x86_64)
   9 url="https://github.com/dtrott/fuse4j"
  10 license=(LGPL)
  11 depends=('java-environment>=5' 'fuse' 'bash')
  12 makedepends=(git maven)
  13 changelog=Changelog
  14 provides=(${_pkgname})
  15 conflicts=(${_pkgname})
  16
  17 _gitroot=git://github.com/dtrott/${_pkgname}.git
  18 _gitname=${_pkgname}
  19
  20 build() {
  21   msg2 "Connecting to GIT server...."
  22   if [ -d "${srcdir}/${_gitname}" ] ; then
  23     ( cd "${srcdir}/${_gitname}" && git pull origin )
  24     msg2 "The local files are updated."
  25   else
  26     git clone $_gitroot "${srcdir}/${_gitname}"
  27   fi
  28
  29   msg2 "Building native libraries and executables..."
  30   cd "${srcdir}/${_gitname}/native"
  31   [[ ${CARCH} = x86_64 ]] && _jdk_arch=amd64 || _jdk_arch=i386
  32   cat <<EOF > make.flags
  33 FUSE_HOME := /usr
  34 JAVA_HOME := /opt/java
  35 INCLUDES := -I\${JAVA_HOME}/include -I\${JAVA_HOME}/include/linux -I\${FUSE_HOME}/include/fuse
  36 LDPATH = -L\${FUSE_HOME}/lib -L\${JAVA_HOME}/jre/lib/${_jdk_arch}/server
  37 LIB_SO=libjavafs.so
  38 FS_EXE=javafs
  39 CC=gcc
  40 DEPFLAGS=-D_FILE_OFFSET_BITS=64
  41 CFLAGS=-Wall -g -fPIC \${DEPFLAGS}
  42 LD=gcc -shared
  43 LDFLAGS=-ljvm -lfuse -lpthread
  44 EOF
  45   make || return 1
  46
  47   msg2 "Building Java libraries..."
  48   cd "${srcdir}/${_gitname}/maven"
  49   mvn --batch-mode --update-snapshots clean install || return 1
  50 }
  51
  52 package() {
  53   msg2 "Install native libraries in /usr/lib..."
  54   install -Dm755 "${srcdir}/${_gitname}/native/libjavafs.so" "${pkgdir}/usr/lib/libjavafs.so"
  55
  56   msg2 "Install java libraries in /usr/share/java/${_pkgname}..."
  57   install -Dm644 "${srcdir}"/${_gitname}/maven/capi-generator/target/capi-generator-*.jar   "${pkgdir}/usr/share/java/${_pkgname}/capi-generator.jar"
  58   install -Dm644 "${srcdir}"/${_gitname}/maven/fuse4j-core/target/fuse4j-core-*.jar         "${pkgdir}/usr/share/java/${_pkgname}/fuse4j-core.jar"
  59   install -Dm644 "${srcdir}"/${_gitname}/maven/fuse4j-fakefs/target/fuse4j-fakefs-*.jar     "${pkgdir}/usr/share/java/${_pkgname}/fuse4j-fakefs.jar"
  60   install -Dm644 "${srcdir}"/${_gitname}/maven/fuse4j-staticfs/target/fuse4j-staticfs-*.jar "${pkgdir}/usr/share/java/${_pkgname}/fuse4j-staticfs.jar"
  61   install -Dm644 "${srcdir}"/${_gitname}/maven/fuse4j-zipfs/target/fuse4j-zipfs-*.jar       "${pkgdir}/usr/share/java/${_pkgname}/fuse4j-zipfs.jar"
  62
  63   msg2 "Install executables in /usr/bin..."
  64   install -Dm755 "${srcdir}/${_gitname}/native/javafs" "${pkgdir}/usr/bin/javafs"
  65
  66   msg2 "Install documentation resources at /usr/share/doc/${pkgname}..."
  67   install -dm755 "${pkgdir}/usr/share/doc/${pkgname}"
  68   cp -a "${srcdir}"/${_gitname}/{extra,README,TODO,TROUBLESHOOTING.txt} "${pkgdir}/usr/share/doc/${pkgname}/"
  69 }
  70
  71 # vim:set ts=2 sw=2 et: