lib32-oxygen-gtk/PKGBUILD

   1 # Maintainer: Hyacinthe Cartiaux <hyacinthe.cartiaux@free.fr>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: birdflesh <antkoul at gmail dot com>
   4 # Contributor: Zephyr
   5
   6 _pkgbasename=oxygen-gtk
   7 pkgname=lib32-${_pkgbasename}
   8 pkgver=1.1.6
   9 pkgrel=1
  10 pkgdesc="Port of the default KDE widget theme (Oxygen) to GTK"
  11 arch=('i686' 'x86_64')
  12 url="http://kde-look.org/content/show.php/?content=136216"
  13 license=('LGPL')
  14 depends=('lib32-gtk2' "${_pkgbasename}" 'lib32-dbus-glib')
  15 makedepends=('cmake' 'gcc-multilib')
  16 source=(ftp://ftp.kde.org/pub/kde/stable/${_pkgbasename}/${pkgver}/src/${_pkgbasename}-${pkgver}.tar.bz2)
  17 md5sums=('714cd895e276cfd20a43b406a78ae6af')
  18
  19 build() {
  20   cd ${srcdir}
  21   mkdir build
  22   cd build
  23
  24   export CC="gcc -m32"
  25   export CXX="g++ -m32"
  26   export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  27
  28   cmake ../${_pkgbasename}-${pkgver} \
  29     -DCMAKE_BUILD_TYPE=Release \
  30     -DCMAKE_INSTALL_PREFIX=/usr \
  31     -DINSTALL_PATH_GTK_ENGINES=/usr/lib32/gtk-2.0/2.10.0/engines
  32   make
  33 }
  34
  35 package() {
  36   cd ${srcdir}/build
  37   make DESTDIR=${pkgdir} install
  38
  39   #Clean up directories provided by x86_64 package
  40   rm -rf ${pkgdir}/usr/bin
  41   rm -rf ${pkgdir}/usr/share
  42 }