gnome-globalmenu-xfce4/PKGBUILD

   1 # Maintainer: SpepS <dreamspepser at yahoo dot it>
   2 # Contributor: Aliaksandr Stelmachonak <mail.avatar at gmail dot com>
   3
   4 _pkg=gnome-globalmenu
   5 pkgname=$_pkg-xfce4
   6 pkgver=0.7.8
   7 pkgrel=7
   8 pkgdesc="Global Menu Bar built for using with Xfce desktop"
   9 url="http://code.google.com/p/gnome2-globalmenu/"
  10 arch=('i686' 'x86_64')
  11 license=('GPL')
  12 depends=('xfce4-panel')
  13 makedepends=('intltool' 'gnome-menus2')
  14 options=('!libtool')
  15 conflicts=('gtk2-aqd' 'gtk2-globalmenu' 'gnome-globalmenu-svn'
  16            'gnome-globalmenu' 'gnome-globalmenu-git')
  17 install=$pkgname.install
  18 source=("http://gnome2-globalmenu.googlecode.com/files/$_pkg-$pkgver.tar.bz2")
  19 md5sums=('c2900eb3ff345457f65d9be2793cc2dc')
  20
  21 build() {
  22   cd "$srcdir/$_pkg-$pkgver"
  23
  24   # Does not build with --as-needed
  25   export LDFLAGS="${LDFLAGS//,--as-needed}"
  26
  27   # fix xfce4 paths retrieving with pkg-config
  28   sed -e "s|\$.*libexec.*\(/xfce4/panel-plugins\)|/usr/lib\1|" \
  29       -e "s|\$.*datadir.*\(/xfce4/panel-plugins\)|/usr/share\1|" \
  30       -i configure
  31
  32   ./configure \
  33         --prefix=/usr \
  34         --sysconfdir=/etc \
  35         --libexecdir=/usr/lib \
  36         --without-gnome-panel \
  37         --with-xfce4-panel \
  38         --disable-tests
  39
  40   make
  41 }
  42
  43 package() {
  44   cd "$srcdir/$_pkg-$pkgver"
  45
  46   make DESTDIR="$pkgdir/" GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 install
  47 }