gzdoom-svn/PKGBUILD

   1 # Contributor: Jan Cholasta <grubber@grubber.cz>
   2 # Maintainer: Jan Cholasta <grubber@grubber.cz>
   3
   4 pkgname=gzdoom-svn
   5 pkgver=860
   6 pkgrel=1
   7 pkgdesc="Doom source port based on ZDoom with an OpenGL renderer."
   8 arch=('i686' 'x86_64')
   9 url="http://grafzahl.drdteam.org/"
  10 license=('custom')
  11 depends=('bzip2' 'gtk2' 'sdl' 'mesa')
  12 makedepends=('nasm' 'cmake' 'subversion')
  13 optdepends=('doom1-wad: Doom shareware IWAD (game data)'
  14             'harmony-wad: Harmony IWAD (game data)'
  15             'heretic1-wad: Heretic shareware IWAD (game data)'
  16             'hexen1-wad: Hexen 1 Demo IWAD (game data)'
  17             'strife0-wad: Strife shareware IWAD (game data)'
  18             'urbanbrawl-wad: Urban Brawl: Action Doom 2 IWAD (game data)')
  19 provides=('gzdoom')
  20 conflicts=('gzdoom')
  21 source=(http://www.fmod.org/index.php/release/version/fmodapi42816linux.tar.gz \
  22         ${pkgname}-sharedir.patch \
  23         gzdoom.desktop \
  24         gzdoom.png)
  25 md5sums=('e6d1a9c8565051a983af7bcc5c4d9cfb'
  26          '0d0b49ae39e1cc827a1098290378c4f9'
  27          '3f5920d839086c9ad04ed1338c3fb546'
  28          '7e1518eeda9bab34b7222a04c690697d')
  29
  30 _svntrunk="http://mancubus.net/svn/hosted/gzdoom/trunk/"
  31 _svnmod="${pkgname}"
  32
  33 _fmodver=4.28.16
  34 _fmod64=
  35
  36 if [ "$CARCH" = "x86_64" ]; then
  37   makedepends[0]='yasm'
  38   source[0]=http://www.fmod.org/index.php/release/version/fmodapi42816linux64.tar.gz
  39   md5sums[0]='b6953f9331c72f9dfa95b31a41aa77b2'
  40   _fmod64=64
  41 fi
  42
  43 build() {
  44   cd "$srcdir"
  45
  46   if [ -d $_svnmod/.svn ]; then
  47     (cd $_svnmod && svn up -r $pkgver)
  48   else
  49     svn co $_svntrunk --config-dir ./ -r $pkgver $_svnmod
  50   fi
  51
  52   msg "SVN checkout done or server timeout"
  53   msg "Starting make..."
  54
  55   rm -rf "$srcdir/$_svnmod-build"
  56   cp -r "$srcdir/$_svnmod" "$srcdir/$_svnmod-build"
  57   cd "$srcdir/$_svnmod-build"
  58
  59   #
  60   # BUILD
  61   #
  62
  63   patch -p1 < ../${pkgname}-sharedir.patch || return 1
  64
  65   cp ../fmodapi${_fmodver//./}linux${_fmod64}/api/lib/libfmodex${_fmod64}-${_fmodver}.so libfmodex-${pkgname}.so || return 1
  66
  67   cmake -DFMOD_INCLUDE_DIR=../fmodapi${_fmodver//./}linux${_fmod64}/api/inc -DFMOD_LIBRARY=libfmodex-${pkgname}.so -DCMAKE_SKIP_RPATH=TRUE . || return 1
  68   make || return 1
  69 }
  70
  71 package() {
  72   cd "$srcdir"/${_svnmod}-build
  73
  74   install -m755 -D gzdoom "$pkgdir"/usr/bin/gzdoom
  75   install -m644 -D gzdoom.pk3 "$pkgdir"/usr/share/games/gzdoom/gzdoom.pk3
  76   install -m644 -D docs/BUILDLIC.TXT "$pkgdir"/usr/share/licenses/${pkgname}/BUILDLIC.TXT
  77   install -m644 -D docs/doomlic.txt "$pkgdir"/usr/share/licenses/${pkgname}/doomlic.txt
  78
  79   install -m755 -D libfmodex-${pkgname}.so "$pkgdir"/usr/lib/libfmodex-${pkgname}.so
  80
  81   install -m644 -D ../gzdoom.png "$pkgdir"/usr/share/pixmaps/gzdoom.png
  82   install -m644 -D ../gzdoom.desktop "$pkgdir"/usr/share/applications/gzdoom.desktop
  83 }