compizconfig-python-ubuntu/PKGBUILD

   1 # Maintainer: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
   2
   3 pkgname=compizconfig-python-ubuntu
   4 _ubuntu_ver=0ubuntu4
   5 pkgver=0.9.5.94.${_ubuntu_ver}
   6 pkgrel=100
   7 pkgdesc="Compizconfig bindings for python - Ubuntu version"
   8 arch=('i686' 'x86_64')
   9 url="http://compiz.org"
  10 license=('GPL')
  11 depends=('compiz-core-ubuntu' 'libcompizconfig-ubuntu' 'glib2' 'python2' 'pyrex')
  12 makedepends=('intltool' 'pkgconfig' 'cython2')
  13 provides=('compizconfig-python')
  14 conflicts=('compizconfig-python')
  15 groups=('unity')
  16 source=("http://archive.ubuntu.com/ubuntu/pool/universe/c/${pkgname%-*}/${pkgname%-*}_${pkgver%.*}.orig.tar.gz"
  17         "http://archive.ubuntu.com/ubuntu/pool/universe/c/${pkgname%-*}/${pkgname%-*}_${pkgver%.*}-${_ubuntu_ver}.diff.gz")
  18 sha512sums=('88bb4e9f481351209c2b05d0f921f86ab4c73ed1dc3db47f9f341b408d6327fbc80adc3901c3e8dc0e5272c0b45cead09c50986b264c01eac94067da2ee6b536'
  19             '38397cf2d82387101bdf0eda1d2a721166111e8fbbcab87602ecbd577413f9e876fe91a677990ae4b24551be710c2cee37389a205aa0aede9775c6beebc489e7')
  20
  21 build() {
  22   cd "${srcdir}/${pkgname%-*}-${pkgver%.*}"
  23
  24   # Apply Ubuntu patches
  25   patch -Np1 -i "${srcdir}/compizconfig-python_${pkgver%.*}-${_ubuntu_ver}.diff"
  26   for i in $(cat 'debian/patches/series' | grep -v '#'); do
  27     patch -Np1 -i "debian/patches/${i}"
  28   done
  29
  30   python2 setup.py build
  31 }
  32
  33 package() {
  34   cd "${srcdir}/${pkgname%-*}-${pkgver%.*}"
  35
  36   python2 setup.py install --prefix="/usr" --root="${pkgdir}"
  37 }