bin32-vmware-server-console/PKGBUILD

   1 # Contributor: Vojtech Horky <vojta . horky at-symbol seznam . cz>
   2 # based on vmware-server-console and bin32-vmware-server PKGBUILDs
   3
   4 pkgname=bin32-vmware-server-console
   5 pkgver=1.0.10
   6 pkgrel=4
   7 pkgdesc="Remote console for VMware Server"
   8 arch=('x86_64')
   9 url="http://www.vmware.com/products/server/"
  10 license=('custom')
  11 depends=('lib32-glibmm' 'lib32-libgnomecanvas' 'lib32-libxdamage' 'lib32-libxt' 'lib32-libxtst' 'lib32-libstdc++5' 'perl')
  12 options=('!strip' '!libtool')
  13 install=bin32-vmware-server-console.install
  14 noextract=(bin32-vmware-server-console-add-libs.tar.gz)
  15 source=(http://download3.vmware.com/software/vmserver/VMware-mui-${pkgver}-203137.tar.gz
  16         http://wiresphere.de/files/vmware-server-console_1.0.8-intrepid-patch.tgz
  17         http://wiresphere.de/files/bin32-vmware-server-console-add-libs.tar.gz
  18         vmware-server-console.desktop
  19         wrapper-gtk24.patch)
  20 md5sums=('0f01e9bdeee3fa2aa84f87f66b69dc83'
  21          '64b74873ab7d677db3a811642e0ae029'
  22          'c756201f7a3356740a549f4b4c31dbd3'
  23          'd5f9319812fffe7bd832a64e1f333231'
  24          '444b6865f665813aaaf751c8ef0c7cd3')
  25
  26 build() {
  27   # unpack the server console package
  28   cd "$srcdir/vmware-mui-distrib/console-distrib"
  29   tar -xzf VMware-server-console-${pkgver}-203137.tar.gz
  30
  31   msg "Patching because of 32bit libraries..."
  32   cd "$srcdir/vmware-mui-distrib/console-distrib/vmware-server-console-distrib/lib/lib"
  33   patch -Np1 -i "$srcdir/wrapper-gtk24.patch"
  34
  35   cd "$srcdir/vmware-mui-distrib/console-distrib/vmware-server-console-distrib"
  36
  37   # Install binary files
  38   mkdir -p "$pkgdir/usr/bin"
  39   install -m755 bin/* "$pkgdir/usr/bin"
  40
  41   # Install libs
  42   mkdir -p "$pkgdir/usr/lib/vmware-server-console"
  43   cp -a lib/* "$pkgdir/usr/lib/vmware-server-console"
  44   chmod -R u+w "$pkgdir/usr/lib/vmware-server-console"
  45
  46   # Install configuration files
  47   install -D -m755 etc/installer.sh "$pkgdir/etc/vmware-server-console/installer.sh"
  48
  49   # Install man page
  50   install -D -m644 man/man1/vmware-server-console.1.gz \
  51     "$pkgdir/usr/share/man/man1/vmware-server-console.1.gz"
  52
  53   # Install license
  54   mkdir -p "$pkgdir/usr/share/licenses/vmware-server-console"
  55   install -m644 doc/{EULA,open_source_licenses.txt} \
  56     "$pkgdir/usr/share/licenses/vmware-server-console"
  57
  58   # Install desktop file
  59   install -D -m644 doc/icon48x48.png \
  60     "$pkgdir/usr/share/pixmaps/vmware-server-console.png"
  61   install -D -m644 "$srcdir/vmware-server-console.desktop" \
  62     "$pkgdir/usr/share/applications/vmware-server-console.desktop"
  63
  64   sed -i "s|/usr|$pkgdir/usr|g" $srcdir/vmware-server-console_1.0.8-intrepid-patch/install
  65   sed -i "s|-C /|-C $pkgdir|g" $srcdir/vmware-server-console_1.0.8-intrepid-patch/install
  66   cd $srcdir/vmware-server-console_1.0.8-intrepid-patch
  67   ./install
  68
  69   tar -C "$pkgdir/usr/lib/vmware-server-console/lib" -xzf "$srcdir/bin32-vmware-server-console-add-libs.tar.gz"
  70
  71   rm -f $pkgdir/usr/bin/vmware-server-console.bkp
  72   rm -f $pkgdir/usr/lib/vmware-server-console/lib/wrapper-gtk24.sh.bkp
  73 }