bumblebee/PKGBUILD

   1 # This script is incomplete and in development.
   2
   3 # Maintainer: Samsagax <samsagax@gmail.com>
   4
   5 pkgname=bumblebee
   6 pkgver=3.0
   7 pkgrel=2
   8 pkgdesc="Bumblebee brings Optimus Support for Linux Through VirtualGL. You need to install proper drivers separately. Can be used with Nouveau or Nvidia"
   9 arch=('i686' 'x86_64')
  10 makedepends=('git')
  11 depends=('virtualgl' 'libbsd' 'glib2')
  12 optdepends=('xf86-video-nouveau: Nouveau driver' 'nouveau-dri: 3D acceleration features fo Nouveau' 'mesa: 3D acceleration features fo Nouveau'  'bbswitch: switch on/off discrete card' 'nvidia-utils-bumblebee: Nvidia utils not breaking LibGL' 'nvidia: Nvidia kernel driver')
  13 if [ "$CARCH" = "x86_64" ]; then
  14      optdepends[${#optdepends[@]}]='lib32-virtualgl: run 32bit applications with optirun'
  15 fi
  16 url="http://www.Bumblebee-Project.org"
  17 license=("GPL3")
  18 install='bumblebee.install'
  19 provides=('bumblebee')
  20 backup=('etc/bumblebee/bumblebee.conf')
  21 source=("https://github.com/downloads/Bumblebee-Project/Bumblebee/${pkgname}-${pkgver}.tar.gz" 'bumblebeed.in')
  22 md5sums=('2ddd4d47bc52aceb3b295e68f9f32ffe'
  23          '8b05da760e9236ecff2c6820616119f7')
  24
  25 build() {
  26     cd "${srcdir}/${pkgname}-${pkgver}"
  27     ./configure \
  28         CONF_DRIVER_MODULE_NVIDIA=nvidia \
  29         CONF_LDPATH_NVIDIA=/usr/lib/nvidia-bumblebee:/usr/lib32/nvidia-bumblebee \
  30         CONF_MODPATH_NVIDIA=/usr/lib/nvidia-bumblebee/xorg/,/usr/lib/xorg/modules \
  31         --prefix=/usr \
  32         --sysconfdir=/etc
  33     make
  34 }
  35
  36 package() {
  37     cd "${srcdir}/${pkgname}-${pkgver}"
  38     make install DESTDIR="$pkgdir"
  39     install -D -m755 "$srcdir/bumblebeed.in" "$pkgdir/etc/rc.d/bumblebeed"
  40     # Make bash_completion work
  41     mv -v "${pkgdir}/etc/bash_completion.d/bumblebee" "${pkgdir}/etc/bash_completion.d/optirun"
  42 }