caml2html/PKGBUILD

   1 # Maintainer: Baptiste Jonglez <zerstorer@free.fr>
   2 pkgname="caml2html"
   3 pkgver=1.4.1
   4 pkgrel=6
   5 pkgdesc="A tool to generate colorized html source from OCaml source code, and much more : LaTeX output, type display on hovering... (standalone binary + OCaml library)"
   6 arch=('i686' 'x86_64')
   7 url="http://martin.jambon.free.fr/caml2html.html"
   8 license=('GPL')
   9 depends=('ocaml')
  10 makedepends=('ocaml-findlib')
  11 conflicts=("${pkgname}-full")
  12 provides=("${pkgname}-full")
  13 options=('!strip')
  14 source=("http://martin.jambon.free.fr/${pkgname}-$pkgver.tar.bz2"
  15         'caml2html.1.gz')
  16 md5sums=('cecc0b3191a99611609a0fb1957c15b6'
  17          '9286b5894e7f2b3ad1156f31b0cc2ff1')
  18 noextract=('caml2html.1.gz')
  19
  20
  21 build() {
  22   cd "$srcdir/${pkgname}-$pkgver"
  23
  24   # making both binary and lib
  25   # see `caml2html' for the standalone binary
  26   PREFIX=/usr make caml2html bytelib optlib
  27
  28   # fix a version number that hasn't been updated
  29   sed -i -e "s/1.3.1/1.4.1/" META
  30
  31   # add `|| true' to prevent make from exiting with error code 1
  32   sed -i -e '38c\
  33         test -f caml2html.cma -o -f caml2html.cmxa && $(MAKE) libinstall || true' Makefile
  34
  35   # change default path for findlib
  36   sed -i -e "s#ocamlfind install#ocamlfind install -destdir $pkgdir$(ocamlfind printconf destdir)#g" Makefile
  37 }
  38
  39 package() {
  40   cd "$srcdir/${pkgname}-$pkgver"
  41
  42   # creating the structure to contain files
  43   mkdir -p "$pkgdir/usr/bin"
  44   mkdir -p "$pkgdir/$(ocamlfind printconf destdir)"
  45
  46   PREFIX="$pkgdir/usr" make install
  47
  48   cd "$srcdir"
  49   mkdir -p "$pkgdir/usr/share/man/man1"
  50   install -m 0644 caml2html.1.gz "$pkgdir/usr/share/man/man1"
  51 }