evince-xps/PKGBUILD

   1 # Maintainer: Ong Kuan Yang <ongkuanyang [at] gmail [dot] com>
   2
   3 pkgname=evince-xps
   4 pkgver=3.0.2
   5 pkgrel=1
   6 pkgdesc="Document viewer compiled with additional xps support"
   7 url="http://projects.gnome.org/evince/"
   8 arch=('i686' 'x86_64')
   9 license=('GPL')
  10 depends=('gtk3' 'libspectre' 'gsfonts' 'poppler-glib' 'djvulibre' 'gnome-icon-theme'
  11          't1lib' 'libgnome-keyring' 'desktop-file-utils' 'dconf' 'gsettings-desktop-schemas' 'libgxps-git')
  12 makedepends=('gnome-doc-utils' 'nautilus' 'texlive-bin' 'intltool' 'gobject-introspection')
  13 optdepends=('texlive-bin: DVI support')
  14 install=evince.install
  15 options=('!libtool' '!emptydirs')
  16 provides=('evince=3.0.2')
  17 conflicts=('evince')
  18 source=(http://ftp.gnome.org/pub/gnome/sources/evince/${pkgver%.*}/evince-${pkgver}.tar.bz2
  19         introspection-fix.patch)
  20 sha256sums=('03abb74620caaa255f2d1369b684bbf8f62e15a4bf2d9f2a45f58e1789295a97'
  21             '897b8c77c5cda31f4f8d860cd6a7ad8ad986dbf3cf26b56acf054cc650e94be1')
  22
  23 build() {
  24   cd "${srcdir}/evince-${pkgver}"
  25
  26   patch -Np1 -i "${srcdir}/introspection-fix.patch"
  27   autoreconf -fi
  28
  29   ./configure --prefix=/usr   --sysconfdir=/etc \
  30       --localstatedir=/var    --libexecdir=/usr/lib/evince \
  31       --disable-static        --enable-nautilus \
  32       --enable-pdf            --enable-tiff \
  33       --enable-djvu           --enable-dvi \
  34       --enable-t1lib          --enable-comics \
  35       --disable-scrollkeeper  --disable-schemas-compile \
  36       --enable-introspection  --enable-xps
  37   make
  38 }
  39
  40 package() {
  41   cd "${srcdir}/evince-${pkgver}"
  42   make DESTDIR="${pkgdir}" install
  43 }