glib-networking-nognome/PKGBUILD

   1 # $Id: PKGBUILD 146052 2012-01-04 17:56:55Z ibiru $
   2 # Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
   3
   4 pkgname=glib-networking-nognome
   5 pkgver=2.30.2
   6 pkgrel=1
   7 pkgdesc="Network-related giomodules for glib without gnome proxy setting support"
   8 arch=('i686' 'x86_64')
   9 url="http://www.gtk.org/"
  10 license=('GPL2')
  11 depends=('glib2' 'libproxy' 'gnutls' 'ca-certificates')
  12 makedepends=('intltool')
  13 provides=('glib-networking')
  14 conflicts=('glib-networking')
  15 options=('!libtool')
  16 install=glib-networking.install
  17 source=(http://download.gnome.org/sources/${pkgname%-nognome}/${pkgver%.*}/${pkgname%-nognome}-$pkgver.tar.xz)
  18 sha256sums=('9f7542500939ca25896f0a74955cd3889758524583f6a15d02e00c9b815559bc')
  19
  20 build() {
  21   cd "$srcdir/${pkgname%-nognome}-$pkgver"
  22   ./configure \
  23     --prefix=/usr --sysconfdir=/etc \
  24     --libexecdir=/usr/lib/glib-networking --disable-static \
  25     --without-gnome-proxy
  26   make
  27 }
  28
  29 package() {
  30   cd "$srcdir/${pkgname%-nognome}-$pkgver"
  31   make DESTDIR="$pkgdir" install
  32 }
  33
  34 # vim:set ts=2 sw=2 et: