graphicsmagick-qd16/PKGBUILD

   1 # Maintainer: kayou <treboloc at laposte dot net>
   2
   3 pkgname=graphicsmagick-qd16
   4 _realname=graphicsmagick
   5 pkgver=1.3.13
   6 pkgrel=1
   7 pkgdesc="Image processing system with options for photivo-hg"
   8 arch=('i686' 'x86_64')
   9 url="http://www.graphicsmagick.org/"
  10 license=('MIT')
  11 makedepends=('perl')
  12 depends=('bzip2' 'freetype2' 'ghostscript' 'jasper' 'lcms2' 'xz' 'libtiff' 'libwmf' 'libsm' 'libxml2' 'libltdl')
  13 provides=('graphicsmagick')
  14 conflicts=('graphicsmagick')
  15 options=('!libtool')
  16 source=("http://downloads.sourceforge.net/project/${_realname}/${_realname}/${pkgver}/GraphicsMagick-${pkgver}.tar.xz")
  17 sha1sums=('b85b21785bb072fd795f7fc6ac902cffae4e96e6')
  18
  19 build() {
  20   cd "${srcdir}/GraphicsMagick-$pkgver"
  21
  22   ./configure \
  23           --prefix=/usr \
  24           --with-perl \
  25           --enable-shared \
  26           --disable-static \
  27           --with-gs-font-dir=/usr/share/fonts/Type1 \
  28           --with-quantum-depth=16 \
  29
  30   make
  31 }
  32
  33 package() {
  34   cd "${srcdir}/GraphicsMagick-$pkgver"
  35
  36   make DESTDIR="${pkgdir}" install
  37
  38   # Install MIT license
  39   install -Dm644 "Copyright.txt" "${pkgdir}/usr/share/licenses/$_realname/Copyright.txt"
  40
  41   # Install perl bindings
  42   # The patching was introduced in order to build perl module without installing package itself and
  43   # not to introduce unnecessary path into LD_RUN_PATH
  44   cd PerlMagick
  45   sed -i -e "s:'LDDLFLAGS'  => \"\(.*\)\":'LDDLFLAGS'  => \"-L${pkgdir}/usr/lib \1\":" Makefile.PL
  46   perl Makefile.PL INSTALLDIRS=vendor PREFIX=/usr DESTDIR="${pkgdir}"
  47   sed -i -e "s/LDLOADLIBS =/LDLOADLIBS = -lGraphicsMagick/" Makefile
  48   make
  49   make install
  50
  51   # Remove perllocal.pod and .packlist
  52   rm -rf "${pkgdir}/usr/lib/perl5/core_perl"
  53   rm "${pkgdir}/usr/lib/perl5/vendor_perl/auto/Graphics/Magick/.packlist"
  54 }