lib32-jasper/PKGBUILD

   1 # Maintainer: josephgbr <rafael.f.f1 at gmail dot com>
   2
   3 _pkgbasename=jasper
   4 pkgname=lib32-$_pkgbasename
   5 pkgver=1.900.1
   6 pkgrel=3
   7 pkgdesc="A software-based implementation of the codec specified in the emerging JPEG-2000 Part-1 standard (32 bit)"
   8 arch=('x86_64')
   9 url="http://www.ece.uvic.ca/~mdadams/jasper/"
  10 license=('custom:JasPer2.0')
  11 depends=('lib32-libjpeg-turbo' 'lib32-freeglut' 'lib32-libxi'
  12          'lib32-libxmu' 'lib32-mesa' "${_pkgbasename}>=${pkgver}" )
  13 makedepends=('unzip' 'gcc-multilib')
  14 options=('!libtool')
  15 source=("http://www.ece.uvic.ca/~mdadams/${_pkgbasename}/software/${_pkgbasename}-${pkgver}.zip"
  16         'jpc_dec.c.patch'
  17         'patch-libjasper-stepsizes-overflow.diff'
  18         'jasper-1.900.1-CVE-2008-3520.patch'
  19         'jasper-1.900.1-CVE-2008-3522.patch')
  20
  21 build() {
  22         cd "${srcdir}/${_pkgbasename}-${pkgver}"
  23
  24         patch -Np1 < "${srcdir}/jpc_dec.c.patch"
  25         patch -Np1 < "${srcdir}/patch-libjasper-stepsizes-overflow.diff"
  26         patch -Np1 < "${srcdir}/jasper-1.900.1-CVE-2008-3520.patch"
  27         patch -Np1 < "${srcdir}/jasper-1.900.1-CVE-2008-3522.patch"
  28
  29         ./configure --prefix=/usr --mandir=/usr/share/man \
  30                         --enable-shared --libdir=/usr/lib32 CC='gcc -m32'
  31         make
  32 }
  33
  34 package() {
  35         cd "${srcdir}/${_pkgbasename}-${pkgver}"
  36
  37         make DESTDIR="${pkgdir}" install
  38         rm -rf ${pkgdir}/usr/{bin,include,share}
  39         install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  40 }
  41
  42 md5sums=('a342b2b4495b3e1394e161eb5d85d754'
  43          '36de7128eea6f701c1e2e13ce5bd8d37'
  44          '24785d8eb3eea19eec7e77d59f3e6a25'
  45          '911bb13529483c093d12c15eed4e9243'
  46          'ed441f30c4231f319d9ff77d86db2ef9')
  47 sha1sums=('9c5735f773922e580bf98c7c7dfda9bbed4c5191'
  48           'c1a0176a15210c0af14d85e55ce566921957d780'
  49           'f298566fef08c8a589d072582112cd51c72c3983'
  50           '2483dba925670bf29f531d85d73c4e5ada513b01'
  51           '0e7b6142cd9240ffb15a1ed7297c43c76fa09ee4')
  52