mf2pt1/PKGBUILD

   1 # Contributor: Patrick McCarty <pnorcks at gmail dot com>
   2
   3 pkgname=mf2pt1
   4 pkgver=2.4.5
   5 pkgrel=3
   6 pkgdesc="Produce PostScript Type 1 fonts from Metafont source"
   7 arch=('i686' 'x86_64')
   8 url="http://www.ctan.org/tex-archive/support/mf2pt1/"
   9 license=('LPPL')
  10 depends=('perl' 't1utils' 'texlive-core')
  11 conflicts=('texlive-core>=2011.24722')
  12 makedepends=('texinfo')
  13 optdepends=('fontforge: support for autohinting Type 1 fonts')
  14 install=$pkgname.install
  15 source=(http://mirror.ctan.org/support/$pkgname.zip)
  16 sha256sums=('e2d137fde6602ac97a2023bb5f0a16c091b8d0061283d353a1509d107f9db14d')
  17
  18 build() {
  19   cd "$srcdir/$pkgname"
  20
  21   mv mf2pt1.pl mf2pt1
  22   mpost -progname=mpost -ini mf2pt1.mp \\dump
  23   makeinfo mf2pt1.texi
  24   pod2man --center="User Commands" --date="2 August 2011" \
  25     --release="v2.4.5" mf2pt1 > mf2pt1.1
  26 }
  27
  28 package() {
  29   cd "$srcdir/$pkgname"
  30
  31   install -D -m755 mf2pt1 "$pkgdir/usr/bin/mf2pt1"
  32
  33   install -D -m644 mf2pt1.mp "$pkgdir/var/lib/texmf/web2c/metapost/mf2pt1.mp"
  34   install -D -m644 mf2pt1.log "$pkgdir/var/lib/texmf/web2c/metapost/mf2pt1.log"
  35   install -D -m644 mf2pt1.info "$pkgdir/usr/share/info/mf2pt1.info"
  36   install -D -m644 mf2pt1.1 "$pkgdir/usr/share/man/man1/mf2pt1.1"
  37
  38   mkdir -p "$pkgdir/usr/share/doc/mf2pt1"
  39   install -D -m644 ChangeLog "$pkgdir/usr/share/doc/mf2pt1/ChangeLog"
  40   install -D -m644 README "$pkgdir/usr/share/doc/mf2pt1/README"
  41   install -D -m644 mf2pt1.pdf "$pkgdir/usr/share/doc/mf2pt1/mf2pt1.pdf"
  42 }