opentyrian-hg/PKGBUILD

   1 # Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
   2 pkgname=opentyrian-hg
   3 pkgver=946
   4 pkgrel=1
   5 pkgdesc="Port of the classic DOS game Tyrian"
   6 url="http://code.google.com/p/opentyrian"
   7 arch=(i686 x86_64)
   8 license=(GPL3 GPL2)
   9 depends=(sdl sdl_net)
  10 makedepends=(mercurial)
  11 source=("http://sites.google.com/a/camanis.net/opentyrian/tyrian/tyrian21.zip")
  12 provides=(tyrian opentyrian)
  13 conflicts=(opentyrian)
  14 replaces=(opentyrian-svn)
  15
  16 _hgroot="http://opentyrian.googlecode.com/hg/"
  17 _hgrepo="opentyrian"
  18
  19 build() {
  20   cd "$srcdir"
  21
  22   msg "Connecting to googlecode.com Mercurial server...."
  23   if [ -d $_hgrepo ]; then
  24     (cd $_hgrepo && hg pull -u)
  25   else
  26     hg clone $_hgroot $_hgrepo
  27   fi
  28
  29   rm -rf $_hgrepo-build
  30   cp -r $_hgrepo $_hgrepo-build
  31   cd $_hgrepo-build
  32
  33   msg "Starting build process."
  34
  35   make release || return 1
  36 }
  37
  38 package() {
  39   cd "$srcdir/$_hgrepo-build"
  40
  41   install -D opentyrian $pkgdir/usr/bin/opentyrian
  42   install -D -m644 linux/man/opentyrian.6 "$pkgdir/usr/share/man/man6/opentyrian.6"
  43   install -D -m644 linux/opentyrian.desktop "$pkgdir/usr/share/applications/opentyrian.desktop"
  44   install -D -m644 linux/icons/tyrian-128.png "$pkgdir/usr/share/pixmaps/opentyrian.png"
  45   for _x in 22 24 32 48 128; do
  46     install -D -m644 "linux/icons/tyrian-$_x.png" "$pkgdir/usr/share/icons/hicolor/${_x}x${_x}/apps/opentyrian.png"
  47   done
  48
  49   cd "$srcdir/tyrian21"
  50   mkdir -p "$pkgdir/usr/share/opentyrian/data"
  51   for _x in *.dat *.lvl *.shp *.snd demo.* music.mus tyrend.anm tyrian.{cdt,hdt,pic} tshp2.pcx; do
  52     install -m644 "$_x" "$pkgdir/usr/share/opentyrian/data/"
  53   done
  54 }
  55
  56 md5sums=('2a3b206a6de25ed4b771af073f8ca904')