perl-travel-routing-de-vrr/PKGBUILD

   1 # Maintainer: Jens Adam (byte/jra) <j_adam@web.de>
   2
   3 _perlmod=Travel-Routing-DE-VRR
   4 pkgname=perl-travel-routing-de-vrr
   5 pkgver=2.00
   6 pkgrel=1
   7 pkgdesc='Unofficial efa.vrr.de command line client and Perl module'
   8 url='http://finalrewind.org/projects/Travel-Routing-DE-VRR/'
   9 license=('custom:WTFPL')
  10 arch=('any')
  11 depends=('perl-class-accessor' 'perl-exception-class' 'perl-libwww' 'perl-xml-libxml')
  12 makedepends=('perl-file-slurp' 'perl-test-compile' 'perl-test-fatal' 'perl-test-pod')
  13 options=('!emptydirs')
  14 source=("http://finalrewind.org/projects/${_perlmod}/${_perlmod}-${pkgver}.tar.gz"
  15         'http://sam.zoy.org/wtfpl/COPYING')
  16 md5sums=('a70155c1d3ad0d35bc18139eeb1bb465'
  17          '389a9e29629d1f05e115f8f05c283df5')
  18
  19 build() {
  20   cd "${srcdir}"/${_perlmod}-${pkgver}
  21   perl Build.PL installdirs=vendor destdir="${pkgdir}"
  22   ./Build
  23 }
  24
  25 check() {
  26   cd "${srcdir}"/${_perlmod}-${pkgver}
  27   ./Build test
  28 }
  29
  30 package() {
  31   cd "${srcdir}"/${_perlmod}-${pkgver}
  32   ./Build install
  33   install -Dm644 ../COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
  34 }