selinux-usr-libselinux/PKGBUILD

   1 # Maintainer: Nicky726 (Nicky726 <at> gmail <dot> com)
   2 # Contributor: Sergej Pupykin (pupykin <dot> s+arch <at> gmail <dot> com)
   3
   4 pkgname=selinux-usr-libselinux
   5 _origname=libselinux
   6 _release=20110727
   7 pkgver=2.1.0
   8 pkgrel=1
   9 pkgdesc="SELinux userspace (libselinux including python bindings)"
  10 arch=('i686' 'x86_64')
  11 url="http://userspace.selinuxproject.org"
  12 license=('GPL')
  13 groups=('selinux' 'selinux-userspace')
  14 depends=('selinux-usr-libsepol>=2.1.0' 'glibc' 'python2')
  15 conflicts=('selinux-usr-libselinux-python')
  16 options=(!emptydirs)
  17 source=(http://userspace.selinuxproject.org/releases/${_release}/devel/${_origname}-${pkgver}.tar.gz)
  18 sha256sums=('fbc4911c1103b00b0530ed21d1004ffa8c661342e1101ccf4c73a573f89f9caf')
  19
  20 build() {
  21   cd "${srcdir}/${_origname}-${pkgver}"
  22   # Meant for python2
  23   sed -i -e "s/shell python -c/shell python2 -c/" "src/Makefile"
  24   make
  25   # Build python wrapper, which is needed for semanage tool
  26   make pywrap
  27 }
  28
  29 package(){
  30   cd "${srcdir}/${_origname}-${pkgver}"
  31   make DESTDIR="${pkgdir}" install
  32   make DESTDIR="${pkgdir}" install-pywrap
  33 }