svc/_svc

   1 #compdef svc
   2
   3 services() {
   4         local -a inits xinetds alls
   5         local expl ret=1
   6
   7         if chkconfig --list > /dev/null 2>&1; then
   8                 alls=( ${(f)"$(LANGUAGE=C LANG=C LC_ALL=C chkconfig --list)"} )
   9                 inits=( ${${${alls[1,(r)xinetd based*]}[1,-2]}/%[[:space:]]*/} )
  10                 xinetds=( ${${${${alls[(r)xinetd based*,-1]}[2,-1]}/#[[:space:]]#}/%:*} )
  11
  12          _alternative \
  13                 'init:init service:compadd -a inits' \
  14             'xinetd:xinetd service:compadd -a xinetds' && ret=0
  15         else
  16                 services_directory=`[ -d /etc/init.d ] && echo /etc/init.d || echo /etc/rc.d`;
  17                 _wanted services expl service compadd "$@" - $services_directory/*(-*:t) && ret=0
  18         fi
  19
  20         return ret
  21 }
  22
  23 init_d() {
  24         local magic cmds what script
  25
  26         _compskip=all
  27
  28         script=$words[1]
  29         [[ $script = */* ]] || script=`[ -d /etc/init.d ] && echo /etc/init.d || echo /etc/rc.d`/$script
  30
  31         what='(st(art|op|atus)|(force-|)re(start|load)|debug_(up|down)|dump(|_stats)|add|delete|clean|list|config(|ure))'
  32
  33         read -u0 -k2 magic < $script && [[ $magic = '#!' ]] &&
  34                 cmds=( ${${(j:|:s:|:)${(M)${(f)"$(< $script)"}:#[[:blank:]]#(\'|)${~what}([[:blank:]]#\|[[:blank:]]#${~what})#(\'|)\)}}//[^-a-z_]} )
  35
  36         (( $#cmds )) || zstyle -a ":completion:${curcontext}:commands" commands cmds ||
  37                 cmds=(start stop)
  38
  39         _sub_commands $cmds
  40 }
  41
  42 _svc() {
  43         case $CURRENT in
  44                 2) # Show services under /etc/rc.d
  45                         services
  46                         ;;
  47                 3) # Show subcommands for current service
  48
  49                         # This is here so that _init_d works on the service name rather
  50                         # than on the actual function name "svc"
  51                         (( CURRENT-- ))
  52                         shift words
  53
  54                         # Append enable and disable as service subcommands
  55                         compadd enable disable
  56
  57                         # Append available subcommands for current service
  58                         init_d
  59                         ;;
  60         esac
  61
  62 }
  63
  64 _svc "$@"